TVertGrid — TStringGrid с возможностью заполнения в design-time

unit VertGrid;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  Grids, stdctrls;

type
  TVertGrid = class(TStringGrid)
  protected
    { Protected declarations }
    procedure SetLines(Value: TStrings);
    function GetLines: TStrings;
    procedure SetTitles(Value: TStrings);
    function GetTitles: TStrings;
  public
    constructor Create(AOwner: TComponent); override;
  published

    // Первая колонка
    property Labels: TStrings read GetLines write SetLines;
    // Первая строка
    property Titles: TStrings read GetTitles write SetTitles;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Samples', [TVertGrid]);
end;

constructor TVertGrid.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);

  ColCount := 2;
  DefaultRowHeight := 16;
end;

procedure TVertGrid.SetLines(Value: TStrings);
begin
  if Value.Count > RowCount then
    RowCount := Value.Count;

  Cols[0].Assign(Value);
end;

procedure TVertGrid.SetTitles(Value: TStrings);
begin
  if Value.Count > ColCount then
    ColCount := Value.Count;

  Rows[0].Assign(Value);
end;

function TVertGrid.GetLines: TStrings;
begin
  result := Cols[0];
end;

function TVertGrid.GetTitles: TStrings;
begin
  result := Rows[0];
end;

end.