Запись и чтение объекта TPersistent в поток

Автор: Mystic

{ **** UBPFD *********** by delphibase.endimus.com ****
>> Запись/чтение объекта TPersistent в поток

Пара функций, выполняющих запись/чтение объекта,
порожденного от TPersistent, в поток.

ВНИМАНИЕ! Код этих процедур основан на VCL пятой версии Delphi.
Вполне возможно, что в последующих версиях Delphi он работать не будет!

Зависимости: Classes
Автор:       Mystic, mystic2000@newmail.ru, ICQ:125905046, Харьков
Copyright:   (c) Mystic
Дата:        25 января 2003 г.
***************************************************** }

unit PersistentIO;

interface

uses Classes;

procedure WritePersistent(S: TStream; Instance: TPersistent);
procedure ReadPersistent(S: TStream; Instance: TPersistent);

implementation

type
  TMyWriter = class(TWriter)
  public
    procedure WritePersistent(Instance: TPersistent);
  end;

procedure TMyWriter.WritePersistent(Instance: TPersistent);
begin
  WriteProperties(Instance);
  WriteListEnd;
end;

type
  TMyReader = class(TReader)
  public
    procedure ReadPersistent(Instance: TPersistent);
  end;

procedure TMyReader.ReadPersistent(Instance: TPersistent);
begin
  while not EndOfList do
    ReadProperty(Instance);
  ReadListEnd;
end;

procedure WritePersistent(S: TStream; Instance: TPersistent);
var
  Writer: TMyWriter;
begin
  Writer := TMyWriter.Create(S, 4096);
  try
    Writer.WritePersistent(Instance);
  finally
    Writer.Free;
  end;
end;

procedure ReadPersistent(S: TStream; Instance: TPersistent);
var
  Reader: TMyReader;
begin
  Reader := TMyReader.Create(S, 4096);
  try
    Reader.ReadPersistent(Instance);
  finally
    Reader.Free;
  end;
end;

end.

Недавно добавленные исходники
• DeLiKaTeS Tetris (Тетрис) 4 539 • TDictionary Custom Sort 6 569 • Fast Watermark Sources 6 341 • 3D Designer 9 290 • Sik Screen Capture 6 675 • Patch Maker 7 047 • Айболит (remote control) 7 059 • ListBox Drag & Drop 5 927 • Доска для игры Реверси 97 392 • Графические эффекты 7 264 • Рисование по маске 6 559 • Перетаскивание изображений 5 426 • Canvas Drawing 5 798 • Рисование Луны 5 501 • Поворот изображения 5 032 • Рисование стержней 3 587 • Paint on Shape 2 842 • Генератор кроссвордов 3 720 • Головоломка Paletto 2 998 • Теорема Монжа об окружностях 3 800 • Пазл Numbrix 2 504 • Заборы и коммивояжеры 3 190 • Игра HIP 2 158 • Игра Go (Го) 2 093 • Симулятор лифта 2 468 • Программа укладки плитки 2 132 • Генератор лабиринта 2 609 • Проверка числового ввода 2 286 • HEX View 2 618 • Физический маятник 2 229