Недавно добавленные исходники

•  TDictionary Custom Sort  522

•  Fast Watermark Sources  884

•  3D Designer  1 816

•  Sik Screen Capture  1 461

•  Patch Maker  1 470

•  Айболит (remote control)  1 393

•  ListBox Drag & Drop  1 168

•  Доска для игры Реверси  21 457

•  Графические эффекты  1 343

•  Рисование по маске  1 283

•  Перетаскивание изображений  1 094

•  Canvas Drawing  965

•  Рисование Луны  807

•  Поворот изображения  764

•  Рисование стержней  806

•  Paint on Shape  492

•  Генератор кроссвордов  756

•  Головоломка Paletto  663

•  Теорема Монжа об окружностях  847

•  Пазл Numbrix  612

•  Заборы и коммивояжеры  839

•  Игра HIP  552

•  Игра Go (Го)  525

•  Симулятор лифта  544

•  Программа укладки плитки  506

•  Генератор лабиринта  561

•  Проверка числового ввода  521

•  HEX View  597

•  Физический маятник  523

•  Задача коммивояжера  557

 
скрыть


Delphi FAQ - Часто задаваемые вопросы

| Базы данных | Графика и Игры | Интернет и Сети | Компоненты и Классы | Мультимедиа |
| ОС и Железо | Программа и Интерфейс | Рабочий стол | Синтаксис | Технологии | Файловая система |



Некоторые модификации методов ReadSection и ReadSections объекта, типа TIniFile



Автор: VID

{ **** UBPFD *********** by delphibase.endimus.com ****
>> Некоторые модификации методов ReadSection и ReadSections объекта, типа TIniFile

Отличие функции ReadSectionEx от метода ReadSection, объекта типа TIniFile,
заключается в том, что размер буффера для сохранения содержимого файла,
не является константой (16Кб, в модуле IniFiles.pas), а представляет собой
переменную величину, значение которой равно размеру файла инициализации
(IniFileName). Таким образом решается проблема, с нехваткой выдыленного
размера оперативной памяти для операции чтения содержимого секции (SectionName).
Так же, в случае успешнонго выполнения чтения секции Ini-файла, функция
возвращает количество строк в заполненном списке (Strings)

Функция ReadSectionsEx имеет те же отличия от метода ReadSection, что и функция
ReadSectionEx от метода ReadSection. Функция ReadSectionsEx помещает в список
Strings все секции указанного INI-файла (IniFileName)

Зависимости: Windows, SysUtils, Classes, IniFiles
Автор:       VID, vidsnap@mail.ru, ICQ:132234868, Махачкала
Copyright:   VID (базируется на коде соответствующих методов, в модуле IniFiles.pas)
Дата:        24 мая 2002 г.
***************************************************** }

unit INIExtension;

interface
uses Windows, SysUtils, Classes, IniFiles;

function ReadSectionsEx(IniFileName: string; Strings: TStrings): Integer;
function ReadSectionEx(IniFileName: string; SectionName: string;
  Strings: TStrings): Integer;

implementation

function ReadSectionsEx(IniFileName: string; Strings: TStrings): Integer;
var
  BufSize: Integer;
  SR: TSearchRec;
  buffer, P: Pchar;
begin
  Result := -1;
  if not FileExists(IniFileName) then
    EXIT;
  FindFirst(IniFileName, faAnyFile, SR);
  BufSize := Sr.Size;
  FindClose(SR);
  GetMem(Buffer, BufSize);
  try
    Strings.BeginUpdate;
    try
      Strings.Clear;
      if GetPrivateProfileSectionNames(buffer, BufSize,
        Pchar(IniFileName)) <> 0 then
      begin
        P := Buffer;
        while P^ <> #0 do
        begin
          Strings.Add(P);
          Inc(P, StrLen(P) + 1);
        end;
      end;
      Result := Strings.Count;
    finally
      Strings.EndUpdate;
    end;
  finally
    FreeMem(Buffer, BufSize)
  end;
end;

function ReadSectionEx(IniFileName: string; SectionName: string;
  Strings: TStrings): Integer;
var
  BufSize: Integer;
  SR: TSearchRec;
  buffer, P: Pchar;
begin
  Result := -1;
  FindFirst(IniFileName, faAnyFile, SR);
  BufSize := Sr.Size;
  FindClose(SR);
  GetMem(Buffer, BufSize);
  try
    Strings.BeginUpdate;
    try
      Strings.Clear;
      if GetPrivateProfileString(PChar(SectionName), nil, nil, Buffer, BufSize,
        PChar(IniFileName)) <> 0 then
      begin
        P := Buffer;
        while P^ <> #0 do
        begin
          Strings.Add(P);
          Inc(P, StrLen(P) + 1);
        end;
      end;
      Result := Strings.Count;
    finally
      Strings.EndUpdate;
    end;
  finally
    FreeMem(Buffer, BufSize)
  end;
end;

end.

Пример использования:

var
  TargetList: TStringList;
  Ini: TIniFile;
begin
  TargetList := TStringList.create;
  Ini := TiniFile.create('system.ini');
  //Заполняем список TargetList параметрами секции boot
  ReadSectionEx(Ini.FileName, 'Boot', TargetList);
  //Заполняем список TargetList именами всех секций
  ReadSectionsEx(Ini.FileName, TargetList);
  Ini.Free;
  TargetList.Free;
end;







Copyright © 2004-2022 "Delphi Sources" by BrokenByte Software. Delphi World FAQ

Группа ВКонтакте   Facebook   Ссылка на Twitter   Ссылка на Telegram