Недавно добавленные исходники

•  TDictionary Custom Sort  3 225

•  Fast Watermark Sources  2 991

•  3D Designer  4 750

•  Sik Screen Capture  3 259

•  Patch Maker  3 467

•  Айболит (remote control)  3 528

•  ListBox Drag & Drop  2 904

•  Доска для игры Реверси  80 780

•  Графические эффекты  3 843

•  Рисование по маске  3 171

•  Перетаскивание изображений  2 544

•  Canvas Drawing  2 672

•  Рисование Луны  2 500

•  Поворот изображения  2 092

•  Рисование стержней  2 120

•  Paint on Shape  1 525

•  Генератор кроссвордов  2 183

•  Головоломка Paletto  1 730

•  Теорема Монжа об окружностях  2 158

•  Пазл Numbrix  1 649

•  Заборы и коммивояжеры  2 016

•  Игра HIP  1 262

•  Игра Go (Го)  1 200

•  Симулятор лифта  1 422

•  Программа укладки плитки  1 177

•  Генератор лабиринта  1 512

•  Проверка числового ввода  1 297

•  HEX View  1 466

•  Физический маятник  1 322

•  Задача коммивояжера  1 357

 
скрыть


Delphi FAQ - Часто задаваемые вопросы

| Базы данных | Графика и Игры | Интернет и Сети | Компоненты и Классы | Мультимедиа |
| ОС и Железо | Программа и Интерфейс | Рабочий стол | Синтаксис | Технологии | Файловая система |



Delphi Sources

Функция возведения в степень



Автор: Александр

{ **** UBPFD *********** by delphibase.endimus.com ****
>> Функция возведения в степень

альтернатива Math.Power

Зависимости: их нет
Автор:       Александр
Copyright:   Александр
Дата:        12 сентября 2003 г.
***************************************************** }

function Degree(const DegBasis, DegParam: Extended): Extended;
asm
        // Вход: DegBasis, DegParam --> в стеке
        // Выход: Result(= DegParam в случае некорректных данных) --> ST(0)

        FLD DegParam
        FLDZ
        FCOMIP ST, ST(1)
        JNZ @@DegParam_is_not_0
        FFREE ST
        FLD1
        JMP @@exit
@@DegParam_is_not_0:
        JNC @@DegParam_is_less_than_0
        XOR EAX, EAX
        JMP @@cmp_DegBasis_to_0
@@DegParam_is_less_than_0:
        OR EAX, 1
@@cmp_DegBasis_to_0:
        FLD DegBasis
        FLDZ
        FCOMIP ST, ST(1)
        JNZ @@DegBasis_is_not_0
        TEST EAX, 1
        JZ @@DegParam_is_greater_than_0
        FSTP ST
        JMP @@exit
@@DegParam_is_greater_than_0:
        FSTP ST(1)
        JMP @@exit
@@DegBasis_is_not_0:
        JC @@DegBasis_is_greater_than_0
        FABS
        FXCH
        OR EAX, 1
        FLD ST
        FRNDINT
        FSUB ST, ST(1)
        FLDZ
        FCOMIP ST, ST(1)
        FSTP ST
        JZ @@DegParam_is_integer
        FLD1
        FDIV ST, ST(1)
        FABS
        FLD1
        FCOMIP ST, ST(1)
        JC @@Abs_1_div_DegParam_greater_than_1
        FSTP ST
        FSTP ST(1)
        JMP @@exit
@@Abs_1_div_DegParam_greater_than_1:
        FISTP QWORD PTR @@Int_64
        TEST BYTE PTR @@Int_64, 1
        JNZ @@change_a_sign_at_the_and_of_calculations
        FSTP ST(1)
        JMP @@exit
@@DegParam_is_integer:
        FLD ST
        FISTP QWORD PTR @@Int_64
        TEST BYTE PTR @@Int_64, 1
        JNZ @@change_a_sign_at_the_and_of_calculations
        XOR EAX, EAX
@@change_a_sign_at_the_and_of_calculations:
        FXCH
@@DegBasis_is_greater_than_0:
        FYL2X
        FLD ST
        FRNDINT
        FSUB ST(1), ST
        FXCH
        F2XM1
        FLD1
        FADD
        FSCALE
        FSTP ST(1)
        TEST EAX, 1
        JZ @@exit
        FCHS
        JMP @@exit
@@Int_64:
        DQ 0
@@exit:
        FWAIT

end;

Пример использования:

Degree(-8, 1 / 3) = -2







Copyright © 2004-2024 "Delphi Sources" by BrokenByte Software. Delphi World FAQ

Группа ВКонтакте