Недавно добавленные исходники

•  DeLiKaTeS Tetris (Тетрис)  3 927

•  TDictionary Custom Sort  6 031

•  Fast Watermark Sources  5 821

•  3D Designer  8 641

•  Sik Screen Capture  6 153

•  Patch Maker  6 594

•  Айболит (remote control)  6 583

•  ListBox Drag & Drop  5 442

•  Доска для игры Реверси  95 376

•  Графические эффекты  6 796

•  Рисование по маске  5 967

•  Перетаскивание изображений  4 970

•  Canvas Drawing  5 343

•  Рисование Луны  5 070

•  Поворот изображения  4 608

•  Рисование стержней  3 266

•  Paint on Shape  2 507

•  Генератор кроссвордов  3 398

•  Головоломка Paletto  2 699

•  Теорема Монжа об окружностях  3 494

•  Пазл Numbrix  2 295

•  Заборы и коммивояжеры  2 985

•  Игра HIP  1 945

•  Игра Go (Го)  1 858

•  Симулятор лифта  2 208

•  Программа укладки плитки  1 931

•  Генератор лабиринта  2 369

•  Проверка числового ввода  2 055

•  HEX View  2 376

•  Физический маятник  2 010

 
скрыть

  Форум  

Delphi FAQ - Часто задаваемые вопросы

| Базы данных | Графика и Игры | Интернет и Сети | Компоненты и Классы | Мультимедиа |
| ОС и Железо | Программа и Интерфейс | Рабочий стол | Синтаксис | Технологии | Файловая система |



Delphi Sources

Элемент управления Edit, реагирующий на событие OnTimer



Как-то раз встала такая проблема: если пользователь какое-то время ничего не вводит в элемент управления Edit, то предупредить его об этом.


unit EditOnTime;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls,
  Forms, Dialogs, ExtCtrls, StdCtrls;

type
  TEditOnTime = class(TEdit)
  private
    FInterval: integer;
    FTimer: TTimer;
    FOnTimer: TNotifyEvent;
    procedure SetInterval(Interval: integer);
    procedure Timer(Sender: TObject);
  protected
    procedure KeyPress(var Key: char); override;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    property Interval: integer read FInterval write SetInterval default 750;
    property OnTimer: TNotifyEvent read FOnTimer write FOnTimer;
end;

procedure register;

implementation

//******************* RegisterComponent
// Здесь мы регистрируем компонент в IDE
procedure register;
begin
  RegisterComponents('MPS', [TEditOnTime]);
end;

//******************* TEditOnTime.SetInterval
// устанавливаем интервал таймера
procedure TEditOnTime.SetInterval(Interval: integer);
begin
  FInterval := Interval;
  if Assigned(FTimer) then
    FTimer.Interval := FInterval;
end;

//******************* TEditOnTime.Create
constructor TEditOnTime.Create(AOwner: TComponent);
begin
  FInterval := 750;
  inherited Create(AOwner);
  if not (csDesigning in ComponentState) then
    try
      FTimer := TTimer.Create(self);
      FTimer.Enabled := false;
      FTimer.Interval := FInterval;
      FTimer.OnTimer := Timer;
    except
      FreeAndNil(FTimer);
    end;
end;

//******************* TEditOnTime.Destroy
destructor TEditOnTime.Destroy;
begin
  if Assigned(FTimer) then
    FreeAndNil(FTimer);
  inherited Destroy;
end;

//******************* TEditOnTime.OnTimer
procedure TEditOnTime.Timer(Sender: TObject);
begin
  FTimer.Enabled := false;
  if Assigned(FOnTimer) then
    FOnTimer(self);
end;

//******************* TEditOnTime.KeyPress
procedure TEditOnTime.KeyPress(var Key: char);
begin
  FTimer.Enabled := false;
  inherited KeyPress(Key);
  FTimer.Enabled := (Text <> '') and Assigned(FTimer)
    and Assigned(FOnTimer);
end;

end.








Copyright © 2004-2025 "Delphi Sources" by BrokenByte Software. Delphi World FAQ

Группа ВКонтакте