Недавно добавленные исходники

•  DeLiKaTeS Tetris (Тетрис)  3 990

•  TDictionary Custom Sort  6 099

•  Fast Watermark Sources  5 898

•  3D Designer  8 726

•  Sik Screen Capture  6 220

•  Patch Maker  6 651

•  Айболит (remote control)  6 643

•  ListBox Drag & Drop  5 501

•  Доска для игры Реверси  95 548

•  Графические эффекты  6 859

•  Рисование по маске  6 056

•  Перетаскивание изображений  5 035

•  Canvas Drawing  5 403

•  Рисование Луны  5 124

•  Поворот изображения  4 669

•  Рисование стержней  3 285

•  Paint on Shape  2 530

•  Генератор кроссвордов  3 419

•  Головоломка Paletto  2 735

•  Теорема Монжа об окружностях  3 519

•  Пазл Numbrix  2 316

•  Заборы и коммивояжеры  3 005

•  Игра HIP  1 959

•  Игра Go (Го)  1 879

•  Симулятор лифта  2 229

•  Программа укладки плитки  1 945

•  Генератор лабиринта  2 380

•  Проверка числового ввода  2 070

•  HEX View  2 392

•  Физический маятник  2 023

 
скрыть

  Форум  

Delphi FAQ - Часто задаваемые вопросы

| Базы данных | Графика и Игры | Интернет и Сети | Компоненты и Классы | Мультимедиа |
| ОС и Железо | Программа и Интерфейс | Рабочий стол | Синтаксис | Технологии | Файловая система |



Delphi Sources

Наклон изображения по вертикали и горизонтали



Автор: Fenik

{ **** UBPFD *********** by delphibase.endimus.com ****
>> Наклон изображения по вертикали и горизонтали

Зависимости: Classes, Graphics
Автор:       Fenik, chook_nu@uraltc.ru, Новоуральск
Copyright:   Автор Федоровских Николай
Дата:        2 июня 2002 г.
***************************************************** }

procedure InclinationBitmap(Bitmap: TBitmap; Hor,
  Ver: Double; BackColor: TColor);

  function Tan(X: Extended): Extended;
    // Tan := Sin(X) / Cos(X)
  asm
        FLD X
        FPTAN
        FSTP ST(0) // FPTAN pushes 1.0 after result
        FWAIT
  end;

type
  TRGB = record
    B, G, R: Byte;
  end;
  pRGB = ^TRGB;
var
  x, y, WW, HH, alpha: Integer;
  OldPx, NewPx: PRGB;
  T: Double;
  Bmp: TBitmap;
begin
  Bitmap.PixelFormat := pf24Bit;
  Bmp := TBitmap.Create;
  try
    Bmp.Assign(Bitmap);
    WW := Bitmap.Width;
    HH := Bitmap.Height;
    if Hor <> 0.0 then
    begin // По горизонтали
      T := Tan(Hor * (Pi / 180));
      Inc(WW, Abs(Round(HH * T)));
      Bitmap.Width := WW;
      Bitmap.Canvas.Brush.Color := BackColor;
      Bitmap.Canvas.FillRect(Rect(0, 0, Bitmap.Width, Bitmap.Height));
      for y := 0 to HH - 1 do
      begin
        if T > 0 then
          alpha := Round((HH - y) * T)
        else
          alpha := -Round(y * T);
        OldPx := Bmp.ScanLine[y];
        NewPx := Bitmap.ScanLine[y];
        Inc(NewPx, Alpha);
        for x := 0 to Bmp.Width - 1 do
        begin
          NewPx^ := OldPx^;
          Inc(NewPx);
          Inc(OldPx);
        end;
      end;
      Bmp.Assign(Bitmap);
    end;
    if Ver <> 0.0 then
    begin // По вертикали
      T := Tan(Ver * (Pi / 180));
      Bitmap.Height := HH + Abs(Round(WW * T));
      Bitmap.Canvas.Brush.Color := BackColor;
      Bitmap.Canvas.FillRect(Rect(0, 0, Bitmap.Width, Bitmap.Height));
      for x := 0 to WW - 1 do
      begin
        if T > 0 then
          alpha := Round((WW - x) * T)
        else
          alpha := -Round(x * T);
        for y := 0 to Bmp.Height - 1 do
        begin
          NewPx := Bitmap.ScanLine[y + alpha];
          OldPx := Bmp.ScanLine[y];
          Inc(OldPx, x);
          Inc(NewPx, x);
          NewPx^ := OldPx^;
        end;
      end;
    end;
  finally
    Bmp.Free;
  end;
end;

Пример использования:

InclinationBitmap(FBitmap, 7.151, -5.8, clWhite); 




Похожие по теме исходники

Изменение цвета изображения

TGIFImage (GIF изображения)

Поворот изображения




Copyright © 2004-2025 "Delphi Sources" by BrokenByte Software. Delphi World FAQ

Группа ВКонтакте