[Maks19]

Здравствуйте, при попытке импортировать файл возникает ошибка "К сожалению нам не удалось найти файл H:\Pro\1.xls. Возможно он был перемещен, переименован"

Код:

ExcelApp := CreateOleObject('Excel.Application');
 ExcelApp.Workbooks.Open('H:\Pro\1.xls')

Файл 1.xls находится в папке с проектом.
Подскажите, почему возникает такая ошибка?

[lmikle]

Ну, для начала проверь, что файл не заблокирован (например, уже не открыт в другой копии Excel'я).

[Maks19]

Excel не запущен. Файл не открыт. После нажатия на команду по которой должен работать код

Код:

ExcelApp := CreateOleObject('Excel.Application');
 ExcelApp.Workbooks.Open('H:\Pro\1.xls')

Excel появляется в списке фоновых процессов.

[lmikle]

Ну, у меня это работает:

Код:

procedure TForm1.Button1Click(Sender: TObject);
var
  ExcelApp : Variant;
  Workbook : Variant;
begin
  ExcelApp := CreateOleObject('Excel.Application');
  Workbook := ExcelApp.Workbooks.Open('C:\Users\xxxxx xxxxxx\Documents\Сказка.Оружие.xls');
  ExcelApp.Visible := True;
end;

только еще в uses руками добавил "ComObj, ActiveX".
Если задать неправильно имя файла (добавил "1" в имя в конце), то действительно вылетает ошибка. Т.е. подозреваю, что все-таки что то не так с именем файла.
Попробуй для начала выбрать файл в OpenDialog:

Код:

procedure TForm1.Button1Click(Sender: TObject);
var
  ExcelApp : Variant;
  Workbook : Variant;
begin
  if OpenDialog1.Execute then
  begin
    ExcelApp := CreateOleObject('Excel.Application');
    Workbook := ExcelApp.Workbooks.Open(OpenDialog1.FileName);
    ExcelApp.Visible := True;
  end;
end;

Тут уж точно имя файла будет правильное.

ЗЫ. Еще вариант - неправльный формат файла.

[Maks19]

Изначально я хотел записать из уже созданного заранее файла Excel с заданным количеством строк и столбцов в массив числовые данные.

Код:

 ExcelApp := CreateOleObject('Excel.Application');
  ExcelApp.Workbooks.Open('C:\Pro\1.xlsx');
xx := ExcelApp.ActiveCell.Row;
 yy := ExcelApp.ActiveCell.Column;
for i:=1 to yy do
   for j:=1 to xx do
   Mas[i,j]:=

Подскажите, к чему надо приравнивать двухмерный массив Mas, чтобы записались данные из 2 столбцов и 5 строк?

[lmikle]

Что то типа того:

Код:

    // Access the first worksheet
    Worksheet := Workbook.Worksheets[1];

    // Access a specific cell (e.g., A1)
    Cell := Worksheet.Cells[1, 1];
    CellValue := Cell.Value;

[Maks19]

Что значит данный код?

Код:

Cell := Worksheet.Cells[1, 1];
CellValue := Cell.Value;

Какого типа должен быть массив куда записывают значения из ячеек Excel?

[lmikle]

Ну. очевидно, сначала получаем сылку на ячейку страницы книги Excel, потом из ячейки получаем значение. Тип - Variant, потом можно попробоывть конвертировать в более удобный тип, если уверен в типе данныз в ячейках, то можно и сразу попробовать.

[Maks19]

А если нужно получить несколько значений из x строк и y столбцов числовых данных?

Код:

ExcelApp := CreateOleObject('Excel.Application');
  ExcelApp.Workbooks.Open('C:\Pro\1.xlsx');
x := ExcelApp.ActiveCell.Row;
 y := ExcelApp.ActiveCell.Column;
for i:=1 to yy do
   for j:=1 to xx do
   Mas[i,j]:=ExcelSheet.Cells[i, j];

Возникает ошибка. В какой момент нужно конвертировать?

[Maks19]

Сообщение от lmikle

Ну. очевидно, сначала получаем сылку на ячейку страницы книги Excel, потом из ячейки получаем значение. Тип - Variant, потом можно попробоывть конвертировать в более удобный тип, если уверен в типе данныз в ячейках, то можно и сразу попробовать.

А сразу как?

[lmikle]

ну, если ты уверен в данных, то можно просто присвоить (либо использовать спец. функцию):

Код:

var
  v : Variant;
  i1, i2 : Integer;
begin
  v := 123;
  i1 := v;
  i2 := VarAsType(v, varInteger);
end;

Если не уверен, то лучше через TryStrToInt (вариант всегда можно конвертировать в строку):

Код:

var
  v : Variant;
  i : Integer;
begin
  v := 123;
  i := StrToIntDef(v, 0);
end;

[Maks19]

И все-таки к чему надо приравнивать двухмерный массив Mas, чтобы записались данные из 2 столбцов и 5 строк?

[lmikle]

Госпадя!!!
Ну надо 30 минут, что бы из кусочков в теме собрать нужный код и отладить его:

Код:

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, ComObj, Vcl.StdCtrls;

type
  TInt2dArray = Array Of Array Of Integer;

  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    procedure ReadInt2dArrayFromExcel(AFileName : String; ASheet, AStartCol, AStartRow, ANan : Integer; var Result : TInt2dArray);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
const
  xlsFile : String = 'c:\Work\test.xls';
var
  arr : TInt2dArray;
  I, J : Integer;
begin
  Memo1.Clear;
  SetLength(arr,2);
  For I := Low(arr) To High(arr) Do
    SetLength(arr[i],5);

  ReadInt2dArrayFromExcel(xlsFile,1,2,2,-1,arr);
  For J := Low(arr[0]) To High(arr[0]) Do
    Memo1.Lines.Add(Format('%d  %d',[arr[0,J], arr[1,J]]));
end;

procedure TForm1.ReadInt2dArrayFromExcel(AFileName : String; ASheet, AStartCol, AStartRow, ANan : Integer; var Result : TInt2dArray);
var
  ExcelApp : Variant;
  WorkBook : Variant;
  WorkSheet : Variant;
  I, J : Integer;
begin
  // Check buffer size
  If (0 = Length(Result)) Or (0 = Length(Result[Low(Result)])) Then
    Raise Exception.Create('Buffer is not configured (cols or rows or both are equal to 0)');

  // Now open Excel and read data into array
  Try
    ExcelApp := CreateOleObject('Excel.Application');
    WorkBook := ExcelApp.Workbooks.Open(AFileName);
    Worksheet := WorkBook.Worksheets[ASheet];

    For I := Low(Result) To High(Result) Do
      For J := Low(Result[i]) To High(Result[i]) Do
        Begin
          Result[I,J] := StrToIntDef(Worksheet.Cells[AStartRow + J, AStartCol + I].Value, ANan);
        End;
    ExcelApp.Quit;
  Finally
    Worksheet := varNull;
    WorkBook := varNull;
    ExcelApp := varNull;
  End;
end;

end.

Параметры функции:
AFileName - полный путь к файлу
ASheet - номер страницы, начинается с 1
AStartCol, AStartRow - первые колонка и строка в экселе с данными
ANan - значение для подстановки, если в ячейке не целое число
Result - массив, куда писать