[Bargest]

Че-то я туплю... Как на WinAPI по-нормальному проверить со стороны сервера, подключен ли клиент?
Пока ничего не придумал лучше, чем

Код:

isize:=send(s,buf,buflen,0);

и если isize=-1 значит ошибка... однако ошибка будет и в случае, если например переполнен буфер клиента.
Или хоть как получить для send код ошибки?

[NumLock]

The Windows Sockets select function determines the status of one or more sockets, waiting if necessary.
int select (
int nfds,
fd_set FAR * readfds,
fd_set FAR * writefds,
fd_set FAR * exceptfds,
const struct timeval FAR * timeout
);

Parameters

nfds
[in] This argument is ignored and included only for the sake of compatibility.

readfds
[in/out] An optional pointer to a set of sockets to be checked for readability.

writefds
[in/out] An optional pointer to a set of sockets to be checked for writability

exceptfds
[in/out] An optional pointer to a set of sockets to be checked for errors.

timeout
[in] The maximum time for select to wait, or NULL for blocking operation.

что-то типа этого:

Код:

procedure check(ASocket: TSocket; ATimeOutWrite: Integer);
var
  ErrorCode: Integer;
  FDSet: TFDSet;
  TimeVal: TTimeVal;
begin
  if ASocket=INVALID_SOCKET then
    raise Exception.Create('invalid socket');
  FD_ZERO(FDSet);
  FD_SET(ASocket, FDSet);
  TimeVal.tv_sec:=ATimeOutWrite div 1000;
  TimeVal.tv_usec:=(ATimeOutWrite mod 1000)*1000;
  select(0, nil, @FDSet, nil, @TimeVal);
  if not FD_ISSET(ASocket, FDSet) then
    raise Exception.Create('exception');
end;

[Bargest]

Спасибо вам!

[Bargest]

Я немного изменил функцию, чтобы она возвращала мне True или False.

Код:

function CheckSock(ASocket: TSocket; ATimeOutWrite: integer): boolean;
var
  ErrorCode: integer;
  FDSet: TFDSet;
  TimeVal: TTimeVal;
begin
  result := false;
  if ASocket = INVALID_SOCKET then
    raise Exception.Create('invalid socket');
  FD_ZERO(FDSet);
  FD_SET(ASocket, FDSet);
  TimeVal.tv_sec := ATimeOutWrite div 1000;
  TimeVal.tv_usec := (ATimeOutWrite mod 1000) * 1000;
  select(0, nil, @FDSet, nil, @TimeVal);
  if FD_ISSET(ASocket, FDSet) then
    result := true;
end;

Однако почему-то мне всегда возвращается TRUE, даже при отключенном клиенте.
В чем ошибка?

[Bargest]

Поднимаю тему снова...

[Bargest]

Ап Ап Ап Ап Ап

[Bargest]

Ну хоть кто-нибудь!

[NumLock]

ну это как бы пример был.
вот:

Код:

function CheckSocket(const ASocket: TSocket; usec: Integer): Boolean;
var
  FDSet: TFDSet;
  TimeVal: TTimeVal;
begin
  if ASocket<>INVALID_SOCKET then
  begin
    FD_ZERO(FDSet);
    FD_SET(ASocket, FDSet);
    TimeVal.tv_sec:=0;
    TimeVal.tv_usec:=usec;
    if select(0, @FDSet, nil, nil, @TimeVal)<>SOCKET_ERROR then Result:=True
    else Result:=False;
  end else Result:=False;
end;

if CheckSocket(sockethandle, 10000микросек) then ...ok... else ...err...

[Bargest]

Странно... При отключенном клиенте возвращает не SOCKET_ERROR (-1) а 1...
Поставил

Код:

k:=select(0, @FDSet, nil, nil, @TimeVal);
if k=0 then ТРУ

Пока вроде работает.

[NumLock]

The select function determines the status of one or more sockets, waiting if necessary, to perform synchronous I/O.
Return Value
The select function returns the total number of socket handles that are ready and contained in the fd_set structures, zero if the time limit expired, or SOCKET_ERROR if an error occurred. If the return value is SOCKET_ERROR, WSAGetLastError can be used to retrieve a specific error code.

handle не перепутал, который передаешь? может серверный передаешь?

[Bargest]

Да нет, передаю нормальный...

[Bargest]

Все никак не разберусь. Вот подробный отчёт:

Код:

k := select(0, @FDSet, nil, nil, @TimeVal);
if k = 0 then
      result := true;

сокет в фунцкию передаю тот же, на который отправляю все данные и с которого читаю.
Так возвращается 0 если нет данных для чтения (нормально), 1 если есть (тоже нормально), но почему-то 1 (а не -1) если сокет закрыть со стороны клиента.

Код:

k := select(0, nil, @FDSet, nil, @TimeVal);
if k = 0 then
      result := true;

так вообще всегда возвращается 1, даже если сокет закрыт.

Текущий способ (первый) не работает, потому что если в течение N-ного времени передаются данные, то соединение слетает (у меня стоит 5 таких проверок по таймеру). Второй - и говорить нечего.

Прошу помочь. Уже не представляю что еще может быть не так.

[NumLock]

ну вот полный пример http://data.cod.ru/82129

-в ASocket храним клиента. изначально он INVALID_SOCKET, т.к. никогда не подключался

Код:

procedure TForm1.FormCreate(Sender: TObject);
begin
  ASocket:=INVALID_SOCKET;
end;

-таймер периодически вызывает CheckSocket и выводит результат в Caption. естественно для никогда не подключавшегося клиента ASocket=INVALID_SOCKET
procedure TForm1.Timer1Timer(Sender: TObject);

Код:

begin
  if CheckSocket(ASocket, 1000) then Caption:='CheckSocket: True' else Caption:='CheckSocket: False';
  Caption:=Caption+' (SocketHandle='+IntToStr(ASocket)+')';
end;

-при нажатии кнопки 1 клиент подключается

Код:

procedure TForm1.Button1Click(Sender: TObject);
begin
  ClientSocket1.Open;
end;

и на сервере происходит событие. запоминаем в ASocket клиента

Код:

procedure TForm1.ServerSocket1ClientConnect(Sender: TObject;
  Socket: TCustomWinSocket);
begin
  Memo1.Lines.Add('ClientConnect');
  ASocket:=ServerSocket1.Socket.Connections[0].SocketHandle;
end;

-теперь таймер говорит, что клиент подключен
-когда нажимаем кнопку 3 клиент закрывает соединение

Код:

procedure TForm1.Button3Click(Sender: TObject);
begin
  ClientSocket1.Close;
end;

и на сервере происходит событие

Код:

procedure TForm1.ServerSocket1ClientDisconnect(Sender: TObject;
  Socket: TCustomWinSocket);
begin
  Memo1.Lines.Add('ClientDisconnect');
end;

но в нем не будем трогать ASocket!!! пусть таймер так для этого клиента и проверяет состояние.
-теперь таймер будет говорить False

полный код:

Код:

unit Unit1;

interface

uses
  WinSock,
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, ScktComp;

type
  TForm1 = class(TForm)
    ClientSocket1: TClientSocket;
    ServerSocket1: TServerSocket;
    Timer1: TTimer;
    Button1: TButton;
    Memo1: TMemo;
    Button2: TButton;
    Button3: TButton;
    ClientSocket2: TClientSocket;
    procedure Button1Click(Sender: TObject);
    procedure ServerSocket1ClientConnect(Sender: TObject;
      Socket: TCustomWinSocket);
    procedure ServerSocket1ClientDisconnect(Sender: TObject;
      Socket: TCustomWinSocket);
    procedure ServerSocket1ClientRead(Sender: TObject;
      Socket: TCustomWinSocket);
    procedure FormCreate(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private declarations }
    ASocket: TSocket;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

function CheckSocket(const ASocket: TSocket; usec: Integer): Boolean;
var
  FDSet: TFDSet;
  TimeVal: TTimeVal;
begin
  if ASocket<>INVALID_SOCKET then
  begin
    FD_ZERO(FDSet);
    FD_SET(ASocket, FDSet);
    TimeVal.tv_sec:=0;
    TimeVal.tv_usec:=usec;
    if select(0, @FDSet, nil, nil, @TimeVal)<>SOCKET_ERROR then Result:=True
    else Result:=False;
  end else Result:=False;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  ClientSocket1.Open;
end;

procedure TForm1.ServerSocket1ClientConnect(Sender: TObject;
  Socket: TCustomWinSocket);
begin
  Memo1.Lines.Add('ClientConnect');
  ASocket:=ServerSocket1.Socket.Connections[0].SocketHandle;
end;

procedure TForm1.ServerSocket1ClientDisconnect(Sender: TObject;
  Socket: TCustomWinSocket);
begin
  Memo1.Lines.Add('ClientDisconnect');
end;

procedure TForm1.ServerSocket1ClientRead(Sender: TObject;
  Socket: TCustomWinSocket);
begin
  Memo1.Lines.Add('ClientRead='+Socket.ReceiveText);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ASocket:=INVALID_SOCKET;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  if CheckSocket(ASocket, 1000) then Caption:='CheckSocket: True' else Caption:='CheckSocket: False';
  Caption:=Caption+' (SocketHandle='+IntToStr(ASocket)+')';
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  ClientSocket1.Socket.SendText('hello');
end;

procedure TForm1.Button3Click(Sender: TObject);
begin
  ClientSocket1.Close;
end;

end.

естественно проверка состояния сокета для не блокируемых сокетов (событийных) это только для примера. там и так ясно когда клиент туту.

[Bargest]

Код:

procedure TServerClientThread.ClientExecute;
var
  FDSet: TFDSet;
  TimeVal: TTimeVal;
begin
  while not Terminated and ClientSocket.Connected do
  begin
    FD_ZERO(FDSet);
    FD_SET(ClientSocket.SocketHandle, FDSet);
    TimeVal.tv_sec := 0;
    TimeVal.tv_usec := 500;
    if (select(0, @FDSet, nil, nil, @TimeVal) > 0) and not Terminated then
      if ClientSocket.ReceiveBuf(FDSet, -1) = 0 then Break
      else Synchronize(DoRead);
    if (select(0, nil, @FDSet, nil, @TimeVal) > 0) and not Terminated then
      Synchronize(DoWrite);
  end;
end;

В компоненте ServerSocket вечно проверяется, есть ли буфер для чтения или записи, если есть для чтения - вызывают функцию его чтения.

Код:

function TCustomWinSocket.ReceiveBuf(var Buf; Count: Integer): Integer;
var
  ErrorCode, iCount: Integer;
begin
  Lock;
  try
    Result := 0;
    if (Count = -1) and FConnected then
      ioctlsocket(FSocket, FIONREAD, Longint(Result))
    else begin
      if not FConnected then Exit;
      if ioctlsocket(FSocket, FIONREAD, iCount) = 0 then
      begin
        if (iCount > 0) and (iCount < Count) then
          Count := iCount;
      end;

      Result := recv(FSocket, Buf, Count, 0);
      if Result = SOCKET_ERROR then
      begin
        ErrorCode := WSAGetLastError;
        if ErrorCode <> WSAEWOULDBLOCK then
        begin
          Error(Self, eeReceive, ErrorCode);
          Disconnect(FSocket);
          if ErrorCode <> 0 then
            raise ESocketError.CreateResFmt(@sWindowsSocketError,
              [SysErrorMessage(ErrorCode), ErrorCode, 'recv']);
        end;
      end;
    end;
  finally
    Unlock;
  end;
end;

Если эту функцию я правильно понял, то получается, что если прочитать не удалось то клиента отключают со стороны сервера.
Тогда не удивительно, что функция для ASocket начинает возвращать ошибку - ведь ASocket это число, ссылка. Сам сокет уже закрыт сервером т.к. была ошибка чтения.

Почитал код ServerSocket - решил встроить такую же проверку в свой код.

Встроил. Вроде работает нормально. Спасибо NumLock, что направили на этот компонент. По умолчанию его в Delphi XE нету...