[v1s2222]

И опять Здравствуйте!
Есть вопрос, про парсинг.
Дан текст и надо проверить на кол-во открывающихся/закрывающихся скобок, и если они не совпадают, то выдать ошибку. Притом:
если скобка (любая) записана в комментарии, то ее считать не надо и
если скобка записана в двойных кавычках "...", то ее тоже считать не надо.
Комментарии могут быть такие:
1. // это одно строчный комментарий (как в делфи)
2. /* это много строчный
комментарий (как в С)
*/

Скобки могут быть такие:
{ }
[ ]
( )
< >

Посылать в гугл не надо, только оттуда... Поэтому ссылки типа " http://www.google.com.ua/search?sour...BB%D1%84%D0%B8 " не подходят.

ЗЫ Обычные функции (delete, pos, posEx) тут, как я думаю, не совсем подойдут, точнее подойдут, но ну уж очень надо сильно много проверок.

Есть идеи?

[v1s2222]

Так же думаю надо вставить приоритет скобок.
Поидее '{' имеет больший приоритет чем '(', а она в свою очередь выше '['...

И вот еще одна проблемка:
({)} так стоять скобки не могут... Вот тут то как раз и начинаются сложности...

Вот только что нашел вот такую реализацию (через стек):

Код:

function Check(const S:string):boolean;
var
 i:integer;
 Stack:TStack;
 c:char;
begin
 Result:=false;
 Stack:=TStack.Create; 
 for i:=1 to Length(S) do 
  begin
   if not (S[i] in ['{','[','(','}',']',')']) then continue;
   if S[i] in ['{','[','('] then Stack.Push(@S[i]) 
   else        
    if Stack.Count>0 then
     begin
      case Char((Stack.Peek)^) of 
       '[': c:=']';                
       '(': c:=')';
       '{': c:='}';
       else c:=Chr(0);
      end;
      if c<>S[i] then           
       begin
        if Stack.Count=0 then ShowMessage('ошибка в '''+S[i]+'') 
                         else ShowMessage('ошибка в '''+c+'');  
        exit;             
       end else Stack.Pop; 
     end else 
     begin
      ShowMessage('ошибка в '''+S[i]+'');
      exit;
     end;
  end;
 if Stack.Count>0 then  
  begin                  
   ShowMessage('ошибка в '''+Char((Stack.Pop)^)+'');
   exit;
  end;
 Stack.Free;  
 Result:=true;
end;

Может есть другой вариант? (хотя и этот не плох, нашел его после создания темы...)

[v1s2222]

Для компиляции выше описанной реализации надо подключить модуль: "Contnrs", для стека.

[yanot]

Почему бы не использовать Pos.
Не так и громоздко

Особо не тестировал, но вроде работает.

Тут нет проверки на обязательный закрывающий комментарий */
и на правильность кавычек

PHP код:

function Valid(Lines: TStrings): boolean;

const
  InnerArr: array[0..3] of char = (
  '{',
  '[',
  '(',
  '<'
  );

  OuterArr: array[0..3] of char = (
  '}',
  ']',
  ')',
  '>'
  );

var
  InnerCount: array[0..3] of integer;
  OuterCount: array[0..3] of integer;
  i, j, a: integer;
  Comment: boolean;
  CommentPos, Pos2: integer;
  Kav: boolean; // Кавычки
  Start: integer;

begin

  for a := 0 to 3 do
  begin
    InnerCount[a] := 0;
    OuterCount[a] := 0;
  end;

  Result := True;
  Comment := False;

  for i := 0 to Lines.Count-1 do
  begin
    if Comment then
    begin
      CommentPos := Pos('*/', Lines[i]);
      if CommentPos = 0 then
        Continue
      else
      begin
        Comment := False;
        Start := CommentPos+2;
      end;
    end
    else
      Start := 1;

    CommentPos := Pos('//', Lines[i]);
    Pos2 := Pos('/*', Lines[i]);
    if (Pos2 > 0) and ((CommentPos = 0) or (Pos2 < CommentPos)) then
    begin
      CommentPos := pos2;
      Comment := True;
    end;

    if CommentPos < Start then
      CommentPos := Length( Lines[i] );

    Kav := False;
    for j := Start to CommentPos do
    begin

      if Lines[i][j] = '"' then
        Kav := not Kav;

      if not Kav then
        for a := 0 to 3 do
        begin
          if Lines[i][j] = InnerArr[a] then
            Inc( InnerCount[a] );

          if Lines[i][j] = OuterArr[a] then
            if InnerCount[a] > OuterCount[a] then
              Inc( OuterCount[a] )
            else
              Result := False;   // Ошибка: закрывающая скобка раньше открывающей
        end;
    end;

  end;

  if Result then
    for a := 0 to 3 do
      if InnerCount[a] <> OuterCount[a] then
      begin
        Result := False;
        Break;
      end;

end; 


[v1s2222]

Ща посмотрим, спасибо! +

Посмотрел, впринципе нормально, но не совсем то что надо. Если например писать:
{ ( } ) - то должна быть ошибка, т.к. нет приоритета скобок, а у тебя все правильно.
Ну да ладно, взял уже пример работы через стек.