Недавно добавленные исходники

•  TDictionary Custom Sort  523

•  Fast Watermark Sources  884

•  3D Designer  1 816

•  Sik Screen Capture  1 461

•  Patch Maker  1 470

•  Айболит (remote control)  1 393

•  ListBox Drag & Drop  1 168

•  Доска для игры Реверси  21 467

•  Графические эффекты  1 344

•  Рисование по маске  1 284

•  Перетаскивание изображений  1 095

•  Canvas Drawing  967

•  Рисование Луны  808

•  Поворот изображения  764

•  Рисование стержней  808

•  Paint on Shape  492

•  Генератор кроссвордов  756

•  Головоломка Paletto  665

•  Теорема Монжа об окружностях  848

•  Пазл Numbrix  613

•  Заборы и коммивояжеры  839

•  Игра HIP  553

•  Игра Go (Го)  525

•  Симулятор лифта  544

•  Программа укладки плитки  507

•  Генератор лабиринта  562

•  Проверка числового ввода  521

•  HEX View  597

•  Физический маятник  524

•  Задача коммивояжера  557

 
скрыть


Delphi FAQ - Часто задаваемые вопросы

| Базы данных | Графика и Игры | Интернет и Сети | Компоненты и Классы | Мультимедиа |
| ОС и Железо | Программа и Интерфейс | Рабочий стол | Синтаксис | Технологии | Файловая система |



Демонстрация DefineProperties



Автор: Mike Scott(Mobius Ltd.)

Хорошо, создайте на основе опубликованного ниже кода модуль PropDemo.pas и добавьте новый компонент в палитру компонентов. Расположите его на форме и сохраните ее. Затем посмотрите файл DFM каким-либо шестнадцатиричным редактором и проверьте наличие определенных свойств по их именнованным тэгам. Вы можете также попробовать закрыть форму и модуль, а затем открыть его с помощью пункта меню File | Open file..., изменив тип файла в выпадающем списке на *.DFM.

Удачи!


unit PropDemo;

{ Демонстрация DefineProperties.

Mike Scott, CIS 100140,2420. }

interface

uses
  SysUtils, WinTypes, WinProcs, Messages, Classes, Graphics, Controls,
  Forms, Dialogs;

type
  TDemoProps = class(TComponent)
  private
    { Private declarations }
    FStringThing: string;
    FThing: record
      i, j, k: integer;
      x, y: real;
      ch: char;
    end;
    procedure ReadStringThing(Reader: TReader);
    procedure WriteStringThing(Writer: TWriter);
    procedure ReadThing(Stream: TStream);
    procedure WriteThing(Stream: TStream);
  protected
    { Protected declarations }
    procedure DefineProperties(Filer: TFiler); override;
  public
    { Public declarations }
    constructor Create(AOwner: TComponent); override;
  published
    { Published declarations }
  end;

procedure Register;

implementation

constructor TDemoProps.Create(AOwner: TComponent);

begin
  inherited Create(AOwner);

  { создайте любые данные, чтобы было что передать в поток}
  FStringThing := 'Всем привет!';
  with FThing do
  begin
    i := 1;
    j := 2;
    k := 3;
    x := PI;
    y := 180 / PI;
    ch := '?';
  end;
end;

procedure TDemoProps.ReadStringThing(Reader: TReader);

begin
  FStringThing := Reader.ReadString;
end;

procedure TDemoProps.WriteStringThing(Writer: TWriter);

begin
  Writer.WriteString(FStringThing);
end;

procedure TDemoProps.ReadThing(Stream: TStream);

begin
  Stream.ReadBuffer(FThing, sizeof(FThing));
end;

procedure TDemoProps.WriteThing(Stream: TStream);

begin
  Stream.WriteBuffer(FThing, sizeof(FThing));
end;

procedure TDemoProps.DefineProperties(Filer: TFiler);

begin
  inherited DefineProperties(Filer);
  Filer.DefineProperty('StringThing', ReadStringThing, WriteStringThing,
    FStringThing <> '');
  Filer.DefineBinaryProperty('Thing', ReadThing, WriteThing, true);
end;

procedure Register;
begin
  RegisterComponents('Samples', [TDemoProps]);
end;

end.








Copyright © 2004-2022 "Delphi Sources" by BrokenByte Software. Delphi World FAQ

Группа ВКонтакте   Facebook   Ссылка на Twitter   Ссылка на Telegram