Форум по Delphi программированию



Вернуться   Форум по Delphi программированию > Все о Delphi > Программа и интерфейс
Ник
Пароль
Регистрация <<         Правила форума         >> FAQ Пользователи Календарь Поиск Сообщения за сегодня Все разделы прочитаны

Ответ
 
Опции темы Поиск в этой теме Опции просмотра
  #1  
Старый 23.07.2016, 11:06
Аватар для M.A.D.M.A.N.
M.A.D.M.A.N. M.A.D.M.A.N. вне форума
Sir Richard Abramson
 
Регистрация: 05.04.2008
Сообщения: 5,503
Версия Delphi: XE10
Репутация: выкл
По умолчанию Средства локализации

Подскажите какое-нибудь хорошее средство локализации софтины. Главные требования — простота с работе, простота локализации.
__________________
— Как тебя понимать?
— Понимать меня не обязательно. Обязательно меня любить и кормить вовремя.


На Delphi, увы, больше не программирую.
Рекомендуемая литература по программированию
Ответить с цитированием
  #2  
Старый 25.07.2016, 09:56
Аватар для Aristarh Dark
Aristarh Dark Aristarh Dark вне форума
Модератор
 
Регистрация: 07.10.2005
Адрес: Санкт-Петербург
Сообщения: 2,903
Репутация: выкл
По умолчанию

Я вот это юзал, довольно удобно и просто.
__________________
Некоторые программисты настолько ленивы, что сразу пишут рабочий код.

Если вас наказали ни за что - радуйтесь: вы ни в чем не виноваты.
Ответить с цитированием
  #3  
Старый 29.07.2016, 22:02
Аватар для M.A.D.M.A.N.
M.A.D.M.A.N. M.A.D.M.A.N. вне форума
Sir Richard Abramson
 
Регистрация: 05.04.2008
Сообщения: 5,503
Версия Delphi: XE10
Репутация: выкл
По умолчанию

Под fmx не захотело работать корректно.
__________________
— Как тебя понимать?
— Понимать меня не обязательно. Обязательно меня любить и кормить вовремя.


На Delphi, увы, больше не программирую.
Рекомендуемая литература по программированию
Ответить с цитированием
  #4  
Старый 02.08.2016, 09:22
Аватар для M.A.D.M.A.N.
M.A.D.M.A.N. M.A.D.M.A.N. вне форума
Sir Richard Abramson
 
Регистрация: 05.04.2008
Сообщения: 5,503
Версия Delphi: XE10
Репутация: выкл
По умолчанию

Кароче, мне лень графоманить статью о том, как можно переводить интерфейс firemonkey, поэтому вот как я сделал:
Код:
unit language;

interface

uses
  System.Types, System.Classes, System.SysUtils, System.Generics.Collections,
  System.JSON,
  FMX.Types, FMX.Styles;

type
  TLang = class sealed
  private
    class var FLangs: TDictionary<string, string>;
    class var FCurrentLang: string;
    class constructor ClassCreate;
    class destructor ClassDestroy;
    class procedure SetCurrentLang(const Value: string); static; inline;
  public
    class procedure LoadLanguages;
    class function Languages: TArray<string>; inline;
    class property CurrentLang: string read FCurrentLang write SetCurrentLang;
  end;

implementation

{ TLang }

function TranslateEx(const AText: string): string;
begin
  if not TLang.FLangs.TryGetValue(TLang.FCurrentLang + AText, Result) then
    Result := AText
end;

class constructor TLang.ClassCreate;
begin
  TLang.FLangs := TDictionary<string, string>.Create;

  CustomTranslateProc := TranslateEx;
end;

class destructor TLang.ClassDestroy;
begin
  CustomTranslateProc := nil;

  TLang.FLangs.Free;
end;

class function TLang.Languages: TArray<string>;
begin
  Result := TLang.FLangs.Keys.ToArray;
end;

class procedure TLang.LoadLanguages;
const
  html_ret: string = '<br>';
  text_ret: string = #13#10;

var
  rs: TResourceStream;
  ss: TStringStream;
  base: TJSONValue;
  it: TJSONValue;
  jdict: TJSONObject;
  i: Integer;
begin
  rs := TResourceStream.Create(HInstance, 'langs', 'LOCAL');
  try
    ss := TStringStream.Create;
    try
      ss.LoadFromStream(rs);

      base := TJSONObject.ParseJSONValue(ss.DataString);
      try
        for it in base.GetValue<TJSONArray>('langs') do
        begin
          jdict := base.GetValue<TJSONObject>(it.Value);
          for i := 0 to jdict.Count - 1 do
            with jdict.Pairs[i] do
              TLang.FLangs.Add(it.Value +
                JsonString.Value.Replace(html_ret, text_ret),
                JsonValue.Value.Replace(html_ret, text_ret));
        end;
      finally
        base.Free;
      end;
    finally
      ss.Free;
    end;
  finally
    rs.Free;
  end;
end;

class procedure TLang.SetCurrentLang(const Value: string);
begin
  FCurrentLang := Value;

  TStyleManager.UpdateScenes;
end;

end.

В коде, где есть чето типа label1.text := 'привет', надо использовать ф-ю translate:
Код:
label1.text := translate('привет, мир');

Привер JSON словаря:
Код:
{
   "langs":[
      "EN"
   ],
   "EN":{
      "привет":"Hello",
      "пока":"Byte, die"
  }
}
__________________
— Как тебя понимать?
— Понимать меня не обязательно. Обязательно меня любить и кормить вовремя.


На Delphi, увы, больше не программирую.
Рекомендуемая литература по программированию
Ответить с цитированием
Этот пользователь сказал Спасибо M.A.D.M.A.N. за это полезное сообщение:
ApxaHGe1 (07.09.2016)
Ответ



Опции темы Поиск в этой теме
Поиск в этой теме:

Расширенный поиск
Опции просмотра

Ваши права в разделе
Вы не можете создавать темы
Вы не можете отвечать на сообщения
Вы не можете прикреплять файлы
Вы не можете редактировать сообщения

BB-коды Вкл.
Смайлы Вкл.
[IMG] код Вкл.
HTML код Выкл.
Быстрый переход


Часовой пояс GMT +3, время: 00:49.


 

Сайт

Форум

FAQ

RSS лента

Прочее

 

Copyright © Форум "Delphi Sources" by BrokenByte Software, 2004-2021

ВКонтакте   Facebook   Twitter   Ссылка на Telegram