[Klyaksa]

Всем привет! Есть такой кусок кода

Код:

....
type
  TForm1 = class(TForm)
    Timer1: TTimer;
    Button1: TButton;
    Timer2: TTimer;
    Image1: TImage;
    funcmish: TCheckListBox;
    l: TLabel;
    Timer3: TTimer;
    Label1: TLabel;
    procedure Timer1Timer(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Timer2Timer(Sender: TObject);
    procedure Timer3Timer(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  bp:bool=true;//___________________
implementation

{$R *.dfm}
.....

В данном случае переменная "bp" при запуске программы будет иметь значение "true". Вопрос таков. Как мне реализовать нечто подобное, только в отдельной процедуре?

[M.A.D.M.A.N.]

Ну явно присвоить, чо.

[Klyaksa]

Логично, но в данном коде

Код:

function klava(key:integer):bool;
var bp:bool;
begin
result:=false;
 if (getasynckeystate(key)<0) then begin
bp:=true;
end;
if (getasynckeystate(key)=0)and(bp) then
begin
bp:=false;
result:=true;
//beep;
end;
end;
/////////////////////////////////////////
function double_klava(key,fkey:integer):bool;
var bp:bool;
begin
result:=false;
 if (getasynckeystate(key)<0)and(getasynckeystate(fkey)=0) then begin
bp:=true;
end;
if (getasynckeystate(key)=0)and(bp) then
begin
bp:=false;
result:=true;
//beep;
end;
end;

здесь не прокатит. Функции работают циклически. При повторном вызова функции "bp" будет всегда "false" или "true" в зависимости от того как прописать в начале функции. Какие есть еще соображения?

[M.A.D.M.A.N.]

Что нужно то? Чтоб локальная переменная где-то запоминалась?

[Klyaksa]

Ну вроде того. Желательно (если возможно) что-бы она запоминалась в той-же функции в которой находится. И не распространялась на другие функции, так как название переменной одинаковое во всех функциях.

[M.A.D.M.A.N.]

Сделай класс-переменную (class var) и используй ее там.

[angvelem]

Можно так:

1. Способ с применением директивы {$J+}/{$J-}:

Код:

procedure TForm1.Button1Click(Sender: TObject);
const
  {$J+} //Директива, разрешающая изменять значения типизированных констант.
  Cnt : Integer = 0;
  {$J-}
begin
  Inc(Cnt);
  ShowMessage('Счётчик нажатий кнопки: ' + IntToStr(Cnt));
end;

2. Способ с применением указателя на типизированную константу:

Код:

procedure TForm1.Button1Click(Sender: TObject);
const
  Cnt : Integer = 0;
var
  PCnt : ^Integer;
begin
  PCnt := @Cnt;
  Inc(PCnt^);
  ShowMessage('Счётчик нажатий кнопки: ' + IntToStr(Cnt));
end;

[M.A.D.M.A.N.]

А такая константа разве не в стеке будет?

[angvelem]

Нет, по сути это глобальная константа, но с ограниченной видимостью.