Форум по Delphi программированию

Delphi Sources



Вернуться   Форум по Delphi программированию > Все о Delphi > Мультимедиа
Ник
Пароль
Регистрация <<         Правила форума         >> FAQ Пользователи Календарь Поиск Сообщения за сегодня Все разделы прочитаны

Ответ
 
Опции темы Поиск в этой теме Опции просмотра
  #1  
Старый 13.07.2007, 22:50
Аватар для <<D>>
<<D>> <<D>> вне форума
Активный
 
Регистрация: 06.05.2007
Адрес: ГДЕ ТО В СОЛНЕЧНОЙ СИСТЕМЕ
Сообщения: 207
Репутация: 15
По умолчанию Как сделать поворот рисунка на определенный градус.

Здрасте всем. Я хочу зделать что-то вроде часов, как на
Windows Vista, но не знаю как повернуть рисунок на определенный
градус. Подскажите мне ПЛИЗ!

______________
P.S. Vista конечно красивая, но не такая она уже и многофункциональная,
к примеру драва на TV Tuner не устанавливаются,
и постоянно просит разрешение на запуск незнакомой программы,
чесно говоря это доканывает.
Ответить с цитированием
  #2  
Старый 13.07.2007, 22:53
Аватар для <<D>>
<<D>> <<D>> вне форума
Активный
 
Регистрация: 06.05.2007
Адрес: ГДЕ ТО В СОЛНЕЧНОЙ СИСТЕМЕ
Сообщения: 207
Репутация: 15
По умолчанию Windows Vista

Да вот еще : реестр у нее какой-то странный, невозможно с ним работать
пока не запустиш от имени Админа.
Ответить с цитированием
  #3  
Старый 14.07.2007, 00:14
Аватар для 4kusNick
4kusNick 4kusNick вне форума
Местный
 
Регистрация: 06.09.2006
Адрес: Россия, Санкт-Петербург
Сообщения: 444
Репутация: 550
По умолчанию

Код:
{**** UBPFD *********** by delphibase.endimus.ru ****

>> Вращение изображения на заданный угол

 

Зависимости: Windows, Classes, Graphics

Автор:       Fenik, chook_nu@uraltc.ru, Новоуральск

Copyright:   Автор Федоровских Николай

Дата:        2 июня 2002 г.

**************************************************** }

 

procedure RotateBitmap(Bitmap: TBitmap; Angle: Double; BackColor: TColor);

type TRGB = record

      B, G, R: Byte;

    end;

    pRGB = ^TRGB;

    pByteArray = ^TByteArray;

    TByteArray = array[0..32767] of Byte;

    TRectList = array [1..4] of TPoint;

 

var x, y, W, H, v1, v2: Integer;

   Dest, Src: pRGB;

   VertArray: array of pByteArray;

   Bmp: TBitmap;

 

procedure SinCos(AngleRad: Double; var ASin, ACos: Double);

begin

   ASin := Sin(AngleRad);

   ACos := Cos(AngleRad);

end;

 

function RotateRect(const Rect: TRect; const Center: TPoint; Angle: Double): TRectList;

var DX, DY: Integer;

     SinAng, CosAng: Double;

   function RotPoint(PX, PY: Integer): TPoint;

   begin

     DX := PX - Center.x;

     DY := PY - Center.y;

     Result.x := Center.x + Round(DX * CosAng - DY * SinAng);

     Result.y := Center.y + Round(DX * SinAng + DY * CosAng);

   end;

begin

   SinCos(Angle * (Pi / 180), SinAng, CosAng);

   Result[1] := RotPoint(Rect.Left, Rect.Top);

   Result[2] := RotPoint(Rect.Right, Rect.Top);

   Result[3] := RotPoint(Rect.Right, Rect.Bottom);

   Result[4] := RotPoint(Rect.Left, Rect.Bottom);

end;

 

function Min(A, B: Integer): Integer;

begin

   if A < B then Result := A

            else Result := B;

end;

 

function Max(A, B: Integer): Integer;

begin

   if A > B then Result := A

            else Result := B;

end;

 

function GetRLLimit(const RL: TRectList): TRect;

begin

   Result.Left := Min(Min(RL[1].x, RL[2].x), Min(RL[3].x, RL[4].x));

   Result.Top := Min(Min(RL[1].y, RL[2].y), Min(RL[3].y, RL[4].y));

   Result.Right := Max(Max(RL[1].x, RL[2].x), Max(RL[3].x, RL[4].x));

   Result.Bottom := Max(Max(RL[1].y, RL[2].y), Max(RL[3].y, RL[4].y));

end;

 

procedure Rotate;

var x, y, xr, yr, yp: Integer;

     ACos, ASin: Double;

     Lim: TRect;

begin

   W := Bmp.Width;

   H := Bmp.Height;

   SinCos(-Angle * Pi/180, ASin, ACos);

   Lim := GetRLLimit(RotateRect(Rect(0, 0, Bmp.Width, Bmp.Height), Point(0, 0), Angle));

   Bitmap.Width := Lim.Right - Lim.Left;

   Bitmap.Height := Lim.Bottom - Lim.Top;

   Bitmap.Canvas.Brush.Color := BackColor;

   Bitmap.Canvas.FillRect(Rect(0, 0, Bitmap.Width, Bitmap.Height));

   for y := 0 to Bitmap.Height - 1 do begin

     Dest := Bitmap.ScanLine[y];

     yp := y + Lim.Top;

     for x := 0 to Bitmap.Width - 1 do begin

       xr := Round(((x + Lim.Left) * ACos) - (yp * ASin));

       yr := Round(((x + Lim.Left) * ASin) + (yp * ACos));

       if (xr > -1) and (xr < W) and (yr > -1) and (yr < H) then begin

         Src := Bmp.ScanLine[yr];

         Inc(Src, xr);

         Dest^ := Src^;

       end;

       Inc(Dest);

     end;

   end;

end;

 

begin

Bitmap.PixelFormat := pf24Bit;

Bmp := TBitmap.Create;

try

   Bmp.Assign(Bitmap);

   W := Bitmap.Width - 1;

   H := Bitmap.Height - 1;

   if Frac(Angle) <> 0.0

     then Rotate

     else

   case Trunc(Angle) of

     -360, 0, 360, 720: Exit;

     90, 270: begin

       Bitmap.Width := H + 1;

       Bitmap.Height := W + 1;

       SetLength(VertArray, H + 1);

       v1 := 0;

       v2 := 0;

       if Angle = 90.0 then v1 := H

                       else v2 := W;

       for y := 0 to H do VertArray[y] := Bmp.ScanLine[Abs(v1 - y)];

       for x := 0 to W do begin

         Dest := Bitmap.ScanLine[x];

         for y := 0 to H do begin

           v1 := Abs(v2 - x)*3;

           with Dest^ do begin

             B := VertArray[y, v1];

             G := VertArray[y, v1+1];

             R := VertArray[y, v1+2];

           end;

           Inc(Dest);

         end;

       end

     end;

     180: begin

       for y := 0 to H do begin

         Dest := Bitmap.ScanLine[y];

         Src := Bmp.ScanLine[H - y];

         Inc(Src, W);

         for x := 0 to W do begin

           Dest^ := Src^;

           Dec(Src);

           Inc(Dest);

         end;

       end;

     end;

     else Rotate;

   end;

finally

   Bmp.Free;

end;

end;

 
 

 

 

 

 

Пример использования:

Code:
 
RotateBitmap(FBitmap, 17.23, clWhite);
 

или

Код:
const

PixelMax = 32768;

 

type

pPixelArray = ^TPixelArray;

TPixelArray = array [0..PixelMax-1] of TRGBTriple;

 

procedure RotateBitmap_ads(SourceBitmap: TBitmap;

out DestBitmap: TBitmap; Center: TPoint; Angle: Double);

var

cosRadians : Double;

inX : Integer;

inXOriginal : Integer;

inXPrime : Integer;

inXPrimeRotated : Integer;

inY : Integer;

inYOriginal : Integer;

inYPrime : Integer;

inYPrimeRotated : Integer;

OriginalRow : pPixelArray;

Radians : Double;

RotatedRow : pPixelArray;

sinRadians : Double;

begin

DestBitmap.Width := SourceBitmap.Width;

DestBitmap.Height := SourceBitmap.Height;

DestBitmap.PixelFormat := pf24bit;

Radians := -(Angle) * PI / 180;

sinRadians := Sin(Radians);

cosRadians := Cos(Radians);

for inX := DestBitmap.Height-1 downto 0 do

begin

   RotatedRow := DestBitmap.Scanline[inX];

   inXPrime := 2*(inX - Center.y) + 1;

   for inY := DestBitmap.Width-1 downto 0 do

   begin

     inYPrime := 2*(inY - Center.x) + 1;

     inYPrimeRotated := Round(inYPrime * CosRadians - inXPrime * sinRadians);

     inXPrimeRotated := Round(inYPrime * sinRadians + inXPrime * cosRadians);

     inYOriginal := (inYPrimeRotated - 1) div 2 + Center.x;

     inXOriginal := (inXPrimeRotated - 1) div 2 + Center.y;

     if (inYOriginal >= 0) and (inYOriginal <= SourceBitmap.Width-1) and

     (inXOriginal >= 0) and (inXOriginal <= SourceBitmap.Height-1) then

     begin

       OriginalRow := SourceBitmap.Scanline[inXOriginal];

       RotatedRow[inY] := OriginalRow[inYOriginal]

     end

     else

     begin

       RotatedRow[inY].rgbtBlue := 255;

       RotatedRow[inY].rgbtGreen := 0;

       RotatedRow[inY].rgbtRed := 0

     end;

   end;

end;

end;

 

{Usage:}

procedure TForm1.Button1Click(Sender: TObject);

var

Center : TPoint;

Bitmap : TBitmap;

begin

Bitmap := TBitmap.Create;

try

   Center.y := (Image.Height div 2)+20;

   Center.x := (Image.Width div 2)+0;

   RotateBitmap_ads(

   Image.Picture.Bitmap,

   Bitmap,

   Center,

   Angle);

   Angle := Angle + 15;

   Image2.Picture.Bitmap.Assign(Bitmap);

finally

   Bitmap.Free;

end;

end;

Сорри за лишние пустые строки.
__________________
THE CRACKER IS OUT THERE

Последний раз редактировалось 4kusNick, 14.07.2007 в 00:17.
Ответить с цитированием
  #4  
Старый 14.07.2007, 00:18
Аватар для 4kusNick
4kusNick 4kusNick вне форума
Местный
 
Регистрация: 06.09.2006
Адрес: Россия, Санкт-Петербург
Сообщения: 444
Репутация: 550
По умолчанию

или

Код:
Код:
function RotateBitmap(var hDIB: HGlobal; radang: Double; clrBack: TColor): Boolean;

// (c) Copyright original C Code: Code Guru 

var

  lpDIBBits: Pointer;

  lpbi, hDIBResult: PBitmapInfoHeader;

  bpp, nColors, nWidth, nHeight, nRowBytes: Integer;

  cosine, sine: Double;

  x1, y1, x2, y2, x3, y3, minx, miny, maxx, maxy, ti, x, y, w, h: Integer;

  nResultRowBytes, nHeaderSize: Integer;

  i, len: longint;

  lpDIBBitsResult: Pointer;

  dwBackColor: DWORD;

  PtrClr: PRGBQuad;

  RbackClr, GBackClr, BBackClr: Word;

  sourcex, sourcey: Integer;

  mask: Byte;

  PtrByte: PByte;

  dwpixel: DWORD;

  PtrDWord: PDWord;

  hDIBResInfo: HGlobal;

begin;

  // Get source bitmap info 

lpbi := PBitmapInfoHeader(GlobalLock(hdIB));

  nHeaderSize := lpbi^.biSize + lpbi^.biClrUsed * SizeOf(TRGBQUAD);

  lpDIBBits := Pointer(Longint(lpbi) + nHeaderSize);

  bpp := lpbi^.biBitCount; // Bits per pixel 

ncolors := lpbi^.biClrUsed; // Already computed when bitmap was loaded 

nWidth := lpbi^.biWidth;

  nHeight := lpbi^.biHeight;

  nRowBytes := ((((nWidth * bpp) + 31) and (not 31)) shr 3);

 

  // Compute the cosine and sine only once 

cosine := cos(radang);

  sine := sin(radang);

 

  // Compute dimensions of the resulting bitmap 

// First get the coordinates of the 3 corners other than origin 

x1 := ceil(-nHeight * sine); // Originally floor at all places 

y1 := ceil(nHeight * cosine);

  x2 := ceil(nWidth * cosine - nHeight * sine);

  y2 := ceil(nHeight * cosine + nWidth * sine);

  x3 := ceil(nWidth * cosine);

  y3 := ceil(nWidth * sine);

 

  minx := min(0, min(x1, min(x2, x3)));

  miny := min(0, min(y1, min(y2, y3)));

  maxx := max(0, max(x1, max(x2, x3)));// added max(0, 

maxy := max(0, max(y1, max(y2, y3)));// added max(0, 

 

w := maxx - minx;

  h := maxy - miny;

 

  // Create a DIB to hold the result 

nResultRowBytes := ((((w * bpp) + 31) and (not 31)) div 8);

  len := nResultRowBytes * h;

  hDIBResInfo := GlobalAlloc(GMEM_MOVEABLE, len + nHeaderSize);

  if hDIBResInfo = 0 then

  begin

    Result := False;

    Exit;

  end;

 

  hDIBResult := PBitmapInfoHeader(GlobalLock(hDIBResInfo));

  // Initialize the header information 

CopyMemory(hDIBResult, lpbi, nHeaderSize);

  //BITMAPINFO &bmInfoResult = *(LPBITMAPINFO)hDIBResult ; 

hDIBResult^.biWidth := w;

  hDIBResult^.biHeight := h;

  hDIBResult^.biSizeImage := len;

  lpDIBBitsResult := Pointer(Longint(hDIBResult) + nHeaderSize);

 

  // Get the back color value (index) 

ZeroMemory(lpDIBBitsResult, len);

  case bpp of

    1:

      begin //Monochrome 

       if (clrBack = RGB(255, 255, 255)) then

          FillMemory(lpDIBBitsResult, len, $ff);

      end;

    4,

    8:

      begin //Search the color table 

       PtrClr := PRGBQuad(Longint(lpbi) + lpbi^.bisize);

        RBackClr := GetRValue(clrBack);

        GBackClr := GetGValue(clrBack);

        BBackClr := GetBValue(clrBack);

        for i := 0 to nColors - 1 do // Color table starts with index 0 

       begin

          if (PtrClr^.rgbBlue = BBackClr) and

            (PtrClr^.rgbGreen = GBackClr) and

            (PtrClr^.rgbRed = RBackClr) then

          begin

            if (bpp = 4) then //if(bpp==4) i = i | i<<4; 

             ti := i or (i shl 4)

            else

              ti := i;

            FillMemory(lpDIBBitsResult, ti, len);

            break;

          end;

          Inc(PtrClr);

        end;// If not match found the color remains black 

     end;

    16:

      begin

        (* When the Compression field is set to BI_BITFIELDS,

        Windows 95 supports

        only the following 16bpp color masks: A 5-5-5 16-bit image, where the blue mask

        is $001F, the green mask is $03E0, and the red mask is $7C00; and a 5-6-5

        16-bit image, where the blue mask is $001F, the green mask is $07E0,

        and the red mask is $F800. *)

        PtrClr := PRGBQuad(Longint(lpbi) + lpbi^.bisize);

        if (PtrClr^.rgbRed = $7c00) then // Check the Red mask 

       begin // Bitmap is RGB555 

         dwBackColor := ((GetRValue(clrBack) shr 3) shl 10) +

            ((GetRValue(clrBack) shr 3) shl 5) +

            (GetBValue(clrBack) shr 3);

        end

        else

        begin // Bitmap is RGB565 

         dwBackColor := ((GetRValue(clrBack) shr 3) shl 11) +

            ((GetRValue(clrBack) shr 2) shl 5) +

            (GetBValue(clrBack) shr 3);

        end;

      end;

    24,

    32:

      begin

        dwBackColor := ((GetRValue(clrBack)) shl 16) or

          ((GetGValue(clrBack)) shl 8) or

          ((GetBValue(clrBack)));

      end;

  end;

 

  // Now do the actual rotating - a pixel at a time 

// Computing the destination point for each source point 

// will leave a few pixels that do not get covered 

// So we use a reverse transform - e.i. compute the source point 

// for each destination point 

 

for y := 0 to h - 1 do

  begin

    for x := 0 to w - 1 do

    begin

      sourcex := floor((x + minx) * cosine + (y + miny) * sine);

      sourcey := floor((y + miny) * cosine - (x + minx) * sine);

      if ((sourcex >= 0) and (sourcex < nWidth) and

        (sourcey >= 0) and (sourcey < nHeight)) then

      begin // Set the destination pixel 

       case bpp of

          1:

            begin //Monochrome 

             mask := PByte(Longint(lpDIBBits) +

                nRowBytes * sourcey +

                (sourcex div 8))^ and ($80 shr

                (sourcex mod 8));

              if mask <> 0 then

                mask := $80 shr (x mod 8);

              PtrByte  := PByte(Longint(lpDIBBitsResult) +

                nResultRowBytes * y + (x div

                8));

              PtrByte^ := PtrByte^ and (not ($80 shr (x mod

                8)));

              PtrByte^ := PtrByte^ or mask;

            end;

          4:

            begin

              if ((sourcex and 1) <> 0) then

                mask := $0f

              else

                mask := $f0;

              mask := PByte(Longint(lpDIBBits) +

                nRowBytes * sourcey +

                (sourcex div 2))^ and mask;

              if ((sourcex and 1) <> (x and 1)) then

              begin

                if (mask and $f0) <> 0 then

                  mask := (mask shr 4)

                else

                  mask := (mask shl 4);

              end;

              PtrByte := PByte(Longint(lpDIBBitsResult) +

                nResultRowBytes * y + (x div

                2));

              if ((x and 1) <> 0) then

                PtrByte^ := PtrByte^ and (not $0f)

              else

                PtrByte^ := PtrByte^ and (not $f0);

              PtrByte^ := PtrByte^ or Mask;

            end;

          8:

            begin

              mask := PByte(Longint(lpDIBBits) +

                nRowBytes * sourcey +

                sourcex)^;

              PtrByte  := PByte(Longint(lpDIBBitsResult) +

                nResultRowBytes * y + x);

              PtrByte^ := mask;

            end;

          16:

            begin

              dwPixel := PDWord(Longint(lpDIBBits) +

                nRowBytes * sourcey +

                sourcex * 2)^;

              PtrDword  := PDWord(Longint(lpDIBBitsResult) +

                nResultRowBytes * y + x * 2);

              PtrDword^ := Word(dwpixel);

            end;

          24:

            begin

              dwPixel := PDWord(Longint(lpDIBBits) +

                nRowBytes * sourcey +

                sourcex * 3)^ and $ffffff;

              PtrDword  := PDWord(Longint(lpDIBBitsResult) +

                nResultRowBytes * y + x * 3);

              PtrDword^ := PtrDword^ or dwPixel;

            end;

          32:

            begin

              dwPixel := PDWord(Longint(lpDIBBits) +

                nRowBytes * sourcey +

                sourcex * 4)^;

              PtrDword := PDWord(Longint(lpDIBBitsResult) +

                nResultRowBytes * y + x * 4);

              PtrDword^ := dwpixel;

            end;

        end; // Case 

     end

      else

      begin

        // Draw the background color. The background color 

       // has already been drawn for 8 bits per pixel and less 

       case bpp of

          16:

            begin

              PtrDWord := PDWord(Longint(lpDIBBitsResult) +

                nResultRowBytes * y + x * 2);

              PtrDword^ := Word(dwBackColor);

            end;

          24:

            begin

              PtrDWord := PDWord(Longint(lpDIBBitsResult) +

                nResultRowBytes * y + x * 3);

              PtrDword^ := PtrDword^ or dwBackColor;

            end;

          32:

            begin

              PtrDWord := PDWord(Longint(lpDIBBitsResult) +

                nResultRowBytes * y + x * 4);

              PtrDword^ := dwBackColor;

            end;

        end;

      end;

    end;

  end;

  GlobalUnLock(hDIBResInfo);

  GlobalUnLock(hDIB);

  GlobalFree(hDIB);

  hDIB := hDIBResInfo;

  Result := True;

end;
__________________
THE CRACKER IS OUT THERE
Ответить с цитированием
  #5  
Старый 14.07.2007, 00:19
Аватар для 4kusNick
4kusNick 4kusNick вне форума
Местный
 
Регистрация: 06.09.2006
Адрес: Россия, Санкт-Петербург
Сообщения: 444
Репутация: 550
По умолчанию

А на счет Висты - отнюдь, если ее настроить, то она вполне конкурентноспособна.
Чтобы не доканывала вопросами, нужно в учетной записи отключить UAC кажись (не помню, как называется)
__________________
THE CRACKER IS OUT THERE
Ответить с цитированием
  #6  
Старый 14.07.2007, 15:54
Аватар для <<D>>
<<D>> <<D>> вне форума
Активный
 
Регистрация: 06.05.2007
Адрес: ГДЕ ТО В СОЛНЕЧНОЙ СИСТЕМЕ
Сообщения: 207
Репутация: 15
По умолчанию

UAC это еще ладно, но вот Реестр там правда плох.
Например я создал свой Плеер который сохраняет всю инфу в
реестр, а виста выдает ошибки при попытке создания новых
ветвей реестра.
Ответить с цитированием
  #7  
Старый 14.07.2007, 16:43
Аватар для 4kusNick
4kusNick 4kusNick вне форума
Местный
 
Регистрация: 06.09.2006
Адрес: Россия, Санкт-Петербург
Сообщения: 444
Репутация: 550
По умолчанию

Ну это все уже оффтоп, но вообще проблемы могут быть при отсутствии должных прав...
__________________
THE CRACKER IS OUT THERE
Ответить с цитированием
  #8  
Старый 15.07.2007, 15:49
Аватар для <<D>>
<<D>> <<D>> вне форума
Активный
 
Регистрация: 06.05.2007
Адрес: ГДЕ ТО В СОЛНЕЧНОЙ СИСТЕМЕ
Сообщения: 207
Репутация: 15
По умолчанию

С этой дискусией про новое творение Microsoft'a совсем забыл тебя
поблагодорить. Итак: С.П.А.С.И.Б.О.
Ответить с цитированием
Ответ


Delphi Sources

Опции темы Поиск в этой теме
Поиск в этой теме:

Расширенный поиск
Опции просмотра

Ваши права в разделе
Вы не можете создавать темы
Вы не можете отвечать на сообщения
Вы не можете прикреплять файлы
Вы не можете редактировать сообщения

BB-коды Вкл.
Смайлы Вкл.
[IMG] код Вкл.
HTML код Выкл.
Быстрый переход


Часовой пояс GMT +3, время: 19:09.


 

Сайт

Форум

FAQ

RSS лента

Прочее

 

Copyright © Форум "Delphi Sources" by BrokenByte Software, 2004-2023

ВКонтакте   Facebook   Twitter