[Kaktuz]

Столкнулся с проблемой определения формата файла. Есть такой код:

Код:

if OpenPictureDialog1.Execute then
  begin
  Bmp := TBitmap.Create;
  Jpg := TJPEGImage.Create;
  Jpg.LoadFromFile(OpenPictureDialog1.FileName);
  Bmp.Assign(Jpg);
  Image1.Picture.Assign(Bmp);
  end;

Как видно мы выбираем файл *.jpg и преобразовываем его в *.bmp после чего уже работаем с ним. Все отлично работает. но вот получается что открывать мы может только *.jpg файлы. хотя можем работать и с *.bmp.
Так вот. Задача состоит в том что бы определить тип открываемого файла и в последствии уже если это *.jpg преобразовать его в *.bmp, а если это и есть *.bmp то оставить без изменений.
Использовать обычный метод определения - это когда по имени файла вырезается текст после точки и определяется тип, как бы так не особо актуален. точек может быть много, да и, а что если *.bmp изображение просто переименован формат на *.jpg. В программах он отображается, но вот в нашем случае тогда возникнет ошибка.
Как то так вообщем чуток запутанно для меня это получилось.

[Amgsys HQ]

Первые байты файла - индентификатор файла, его настоящее расширение. Считывай их и проверяй.

[Pyro]

...обычный метод определения...

ExtractFileExt

[angvelem]

Я проверяю так:

Код:

type
  TTypeFile		= (tfBMP, tfICON, tfCURSOR, tfWAVE, tfMIDI, 
			   tfHUC, tfJPG,  tfGIF,    tfTIF,  tfMO3, 
			   tfPNG, tfPCX,  tfUnknown);
const
  THeaderFile		: array[0..11, 0..6] of Byte = (
  {BMP}			($42, $4D,   0,   0,   0,   0, 2),
  {ICON}  		(  0,   0,   1,   0,   0,   0, 4),
  {CURSOR}		(  0,   0,   2,   0,   0,   0, 4),
  {WAVE}		($52, $49, $46, $46,   0,   0, 4),
  {MIDI}		($4D, $54, $68, $64,   0,   0, 4),
  {HUC}			($48, $55, $43,   0,   0,   0, 3),
  {JPG}			($FF, $D8, $FF,   0,   0,   0, 3),
  {GIF}			($47, $49, $46, $38,   0,   0, 4),
  {TIF}			($49, $49, $2A, $00,   0,   0, 4),
  {MO3}			($4D, $4F, $33, $04,   0,   0, 4),
  {PNG}			($89, $50, $4E, $47, $0D, $0A, 6),
  {PCX}			($0A, $05,   0,   0,   0,   0, 2));

function CheckTypeFile(P : Pointer) : TTypeFile;
var
  I	: Integer;
begin
  Result := tfUnknown;
  for I := Low(THeaderFile) to High(THeaderFile) do
    if CompareMem(P, @THeaderFile[i], THeaderFile[i][High(THeaderFile[0])]) then
    begin
      Result := TTypeFile(I);
      Break;
    end;
end;

[Kaktuz]

Побайтно... Первые символы... Вроде понятно. Но! Это получается идут HEX данные, с которыми я так толком и не разобрался

[angvelem]

Чего с ними разбираться? 255=$FF и так далее. Обычный калькулятор меняет представление с HEX на DEC и обратно по клавишам F5, F6.
Читаешь файл или часть файла в MemoryStream и отадаёшь в функцию:

Код:

var
  TF : TTypeFile;
begin
...
  // что в потоке
  TF := CheckTypeFile(MemStream.Memory);
...

[Kaktuz]

Сообщение от angvelem

Чего с ними разбираться? 255=$FF и так далее. Обычный калькулятор меняет представление с HEX на DEC и обратно по клавишам F5, F6.
Читаешь файл или часть файла в MemoryStream и отадаёшь в функцию:

Код:

var
  TF : TTypeFile;
begin
...
  // что в потоке
  TF := CheckTypeFile(MemStream.Memory);
...

Для того кто понял суть как это работает все просто, но мне пока месть еще не совсем понятно. Уже пытались объяснить, но опять таки все одни догадки...

[PhoeniX]

Мой экстрасенсорный дар подсказывает мне, что у мсье сложности с 16-ричной системой счисления?

[angvelem]

Собственно, для начала, хватит и тех форматов, что у меня описаны. Лишние не сложно выбросить (HUC нигде и никогда не встретишь).
К примеру:

Код:

  {BMP}			($42, $4D,   0,   0,   0,   0, 2),

последний число (2) показывает, сколько чисел нужно сравнить. Для BMP, как раз достаточно 2.

[Kaktuz]

Вообщем у меня так получилось. не знаю на сколько это правильно. Хотя для проверки этого будет достаточно, но вот для преобразования всего файла в HEX данные нет.

Код:

procedure TForm1.Button1Click(Sender: TObject);
var
  Typ: TStringList;
  a,b: string;
begin
If OpenDialog1.Execute then
  begin
  Typ := TStringList.Create;
  Typ.LoadFromFile(OpenDialog1.FileName);
  a:=Typ.Text;
  b :=
  IntToHex(Ord(a[1]), 2)+
  IntToHex(Ord(a[2]), 2)+
  IntToHex(Ord(a[3]), 2);
  // --- ///
  if b = '89504E' then ShowMessage('PNG');
  if b = 'FFD8FF' then ShowMessage('JPG');
  if b = '424DFA' then ShowMessage('BMP');
  end;
end;

[angvelem]

Понял твою проблему. Понятие DEC, HEC это для человека. Комп работает в бинарной системе. Ничего не нужно конвертить, считываешь в поток и отдаёшь функции. А уж ответ проверяешь через case.

[lmikle]

Сообщение от Kaktuz

Вообщем у меня так получилось. не знаю на сколько это правильно. Хотя для проверки этого будет достаточно, но вот для преобразования всего файла в HEX данные нет.
<skip>

Маньяк.

Код:

var
  Stream : TFileStream;
  Buf : Pointer;
begin
  GetMEm(Buf,5);
  Stream := TFileStream.Create(AFileName,fmOpenRead);
  Try
    Stream.ReadBuffer(Buf^,5);
    case CheckTypeFile(Buf) of // Функуию тебе дали...
       // Здесь работаешь уже с опр. типом
      tfBMP : Begin ... End;
      Else Raise Exception.Create('Unknown format');
    end;
  Finally
    Stream.Free;
    FreeMem(Buf,5);
  End;
end;

[angvelem]

Только маленькая поправка, запросить нужно 7 байт. 6 на определение формата и дополнительный - на длину проверки. Хотя... как определение типа переписать.

[lmikle]

Не, запрашивать надо 6 (моя ошибка, невнимательно посмотрел), а функцию тоже надо поправить, что бы она проверяла кол-во байт, которое указано в последнем элементе массива. Или массив по другому организовать, например как-то так:

Код:

type
  TFormatSample = record
     CheckLength : Integer;
     Sample : Array [0..5] Of Byte;
  end;

const
  THeaderFile	: array[0..11] of TFormatSample = (
  {BMP}	        CheckLength: 2; Sample: ($42, $4D,   0,   0,   0,   0),
                        ...);

Ну и функцию соотв. образом поправить.

[angvelem]

Если таким способом, то да 6 байт, но я особенно не заморачивался с созданием структуры, хотя так удобнее, а "танцевал" от формата PNG, у него самая длинная "шапка" для определения и добавил 7-ой байт с длиной проверки. И функция не проверяет длину, а просто подставляет в CompareMem последний байт из массива.