[plt]

Здравствуйте, столкнулся с необходимостью изменить стандартный белый фон окна типа edit, созданного функцией CreateWindowEx. В какую сторону копать? WNDCLASS или SetBkColor? Пока ни тот, ни другой вариант к положительному результату не привели. Может кто сталкивался с подобной задачей?
Заранее благодарен за помощь!

[NumLock]

WM_CTLCOLOREDIT
By responding to this message, the parent window can use the specified device context handle to set the text and background colors of the edit control.

Код:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    ABrush: HBRUSH;
    AWnd: HWND;
    procedure WMCTLCOLOREDIT(var Msg: TMessage); message WM_CTLCOLOREDIT;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  ABrush:=CreateSolidBrush($ff0000);
  AWnd:=CreateWindowEx(WS_EX_CLIENTEDGE,
  'EDIT',
  'null',
  WS_CHILD or WS_VISIBLE,
  10, 10, 100, 50,
  Handle, 0, HInstance, nil
  );
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  DestroyWindow(AWnd);
  DeleteObject(ABrush);
end;

procedure TForm1.WMCTLCOLOREDIT(var Msg: TMessage);
begin
  if HWND(Msg.LParam)=AWnd then
  begin
    Msg.Result:=ABrush;
    SetTextColor(Msg.WParam, $ffff);
    SetBkMode(Msg.WParam, TRANSPARENT);
  end else inherited;
end;

end.

[plt]

Спасибо! А как заставить этот способ работать в случае, если edit получил сообщение EM_SETREADONLY?

[NumLock]

в MSDN про это написано:

Read-only or disabled edit controls do not send the WM_CTLCOLOREDIT message; instead, they send the WM_CTLCOLORSTATIC message.

т.е. дополняем так:

Код:

    procedure WMCTLCOLORSTATIC(var Msg: TMessage); message WM_CTLCOLORSTATIC;

procedure TForm1.WMCTLCOLORSTATIC(var Msg: TMessage);
begin
  if HWND(Msg.LParam)=AWnd then
  begin
    Msg.Result:=ABrush;
    SetTextColor(Msg.WParam, $ffff);
    SetBkMode(Msg.WParam, TRANSPARENT);
  end else inherited;
end;

[plt]

Большое спасибо!
я как-то не догадался искать решение в этом разделе msdn