[cadil]

Есть процедура, которая отображает язык из трея на поле формы:

Код:

procedure TForm1.TimerKTimer(Sender: TObject);
var
  buf: array [0..$ff] of Char;
begin
   if getasynckeystate($61)<>0 then
EditAdd.Text:='1';
  GetKeyboardLayoutName(buf);
  if ((StrPas(buf)= '00020409') or (StrPas(buf)= '00000409')) then LabelK.Caption:='EN';
  if StrPas(buf)= '00000419' then LabelK.Caption:='RU';
end;

Эта процедура работает, когда окно программы активно.
Помогите организовать эту процедуру так, чтобы она отображала состояние клавиатуры (язык) в том случае, когда программа находится в пассивном состоянии - по аналогии, например, с перехватом клавиш:

Код:

if getasynckeystate($61)<>0 then
EditAdd.Text:='1';

Спасибо!

[NumLock]

как эта программа показывает язык в трее?
http://data.cod.ru/112448

[cadil]

Сообщение от NumLock

как эта программа показывает язык в трее?
http://data.cod.ru/112448

язык ИЗ трея (дублирует!)

[NumLock]

ну. если в трее RU, то показывает русский флаг, если EN, то американский.

[cadil]

Тема висит уже 5 дней и не одного сообщения по сути. А жаль ...
Для меня эта задачка очень актуальна.
Помогите, хотя бы, найти код для виртуальных клавиш Shift+Alt (переключение языка).
Спасибо!

[NumLock]

cadil , ты не отвечаешь на мой ответ с ноября прошлого года
>твоя программа должна отображать язык текстом в поле на форме аналогично тому, как приведеная выше программа отображает язык в трее флагом? та программа не то, что не активна, у нее даже формы нет!
про перехват клавиш вообще не понял к чему...

есть модуль KeyboardLayout. в нем функция:
function NeedKeyboardLayout: Cardinal;

Код:

implementation

uses KeyboardLayout;

Edit1.Text:=IntToStr(NeedKeyboardLayout);

http://narod.ru/disk/17533643001/Key...ayout.dcu.html

[Страдалецъ]

В общем где-то так:

Код:

  
type
  TForm1 = class(TForm)
    Label1: TLabel;
  private
    procedure InputLanguageChanged(var message: TMessage); message WM_INPUTLANGCHANGE;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.InputLanguageChanged(var Message: TMessage);
Var
 Rus, Eng: HKL;
begin
 inherited;
 Rus := LoadKeyboardLayout('00000419', 0);
 Eng := LoadKeyboardLayout('00000409', 0);
 if Message.lParam = Rus then Label1.Caption := 'Русский';
 if Message.lParam = Eng then Label1.Caption := 'Английский';
end;

[NumLock]

функция:

Код:

function NeedKeyboardLayout: Cardinal;
var
  hForegroundWindow: THandle;
  idProcess: DWORD;
begin
  hForegroundWindow:=GetForegroundWindow;
  idProcess:=GetWindowThreadProcessId(hForegroundWindow);
  Result:=LOWORD(GetKeyboardLayout(idProcess));
end;

использование в таймере, к примеру:

Код:

procedure TForm1.Timer1Timer(Sender: TObject);
var
  kbl: Cardinal;
begin
  kbl:=NeedKeyboardLayout;
  Label1.Caption:=IntToStr(kbl);
  case kbl of
    $409: Label2.Caption:='en';
    $419: Label2.Caption:='ru';
    else Label2.Caption:='oops';
  end;
end;

[cadil]

Сообщение от Страдалецъ

В общем где-то так:

Похоже я недостаточно ясно обозначил задачу:
Оператор работает с двумя программами. Одна из них развертывается на весь экран, закрывая при этом линейку меню "Пуск" и, соответственно, состояние клавиатуры в трее. Текст, набираемый в этой программе, переносится (захватывается, экспортируется) в чужое (другое) окно (программа, с кодами которой я работаю), которая располается поверх всех развернутых окон.
Например, нажимаешь букву "П", а печатается "G" - информация о языке не видна!
Хотелось бы сделать так, чтобы

Код:

Label1.Caption := 'Русский';
Label1.Caption := 'Английский';

менялись не только в активном, но и ПАССИВНОМ состоянии программы.
Спасибо!

[Страдалецъ]

Сообщение от cadil

Хотелось бы сделать так, чтобы

Код:

Label1.Caption := 'Русский';
Label1.Caption := 'Английский';

менялись не только в активном, но и ПАССИВНОМ состоянии программы.
Спасибо!

Согласен, не работает этот способ для фонового окна. Пока тут проводил эксперементы доперло, что можно еще проще это делать, вообще без обработки сообщений:

Код:

procedure TForm1.Timer1Timer(Sender: TObject);
Var CurrentLayout: HKL;
begin
 CurrentLayout := GetKeyboardLayout(0);
 if CurrentLayout = Rus then Label1.Caption := 'Русский';
 if CurrentLayout = Eng then Label1.Caption := 'Английский';
end;

Но вот только это не решает изначальную задачу. Будучи фоновым окном, данный код перестает правильно работать, а вот таймер при этом исправно работает и в фоне.
А вот почему это происходит я что-то не догоняю.

[Страдалецъ]

Возникла такая мысль, а не создается ли для каждого окна свой личный KeyboardLayout? Ведь именно такое мы и наблюдаем, каждое окно может иметь свою текущую раскладку и тогда понятно почему смена раскладки в активном окне никак не влияет на неактивное.

[lmikle]

Сообщение от Страдалецъ

Возникла такая мысль, а не создается ли для каждого окна свой личный KeyboardLayout? Ведь именно такое мы и наблюдаем, каждое окно может иметь свою текущую раскладку и тогда понятно почему смена раскладки в активном окне никак не влияет на неактивное.

Именно!
Так что надо делать хук на смену языка и менять Layout для конуретной программы.

[NumLock]

попробую в 3-ий раз показать) уже программа целиком:

Код:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Label1: TLabel;
    Timer1: TTimer;
    procedure Timer1Timer(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Timer1Timer(Sender: TObject);
var
  hForegroundWindow: THandle;
  idProcess: DWORD;
  kbl: Cardinal;
begin
  hForegroundWindow:=GetForegroundWindow;
  idProcess:=GetWindowThreadProcessId(hForegroundWindow);
  kbl:=LOWORD(GetKeyboardLayout(idProcess));
  case kbl of
    $409: Label1.Caption:='Английский';
    $419: Label1.Caption:='Русский';
    else Label1.Caption:='Неизвестный';
  end;
end;

end.

не важно активно окно программы или нет - в любом случае показывает язык ввода активного окна.

[Страдалецъ]

не важно активно окно программы или нет - в любом случае показывает язык ввода активного окна.

Вот она фраза которая для меня все расставила по местам. Действительно, зачем лезть так далеко, когда надо просто работать с активным окном.
Не зря говорят правильно заданный вопрос содержит 90% ответа.

[cadil]

Сообщение от NumLock

попробую в 3-ий раз показать) уже программа целиком:
...
не важно активно окно программы или нет - в любом случае показывает язык ввода активного окна.

Искренне благодарю за терпение и выполненную работу. Это то, что нужно!
Наилучшие пожелания - Страдалецъ.
Удач!