delphi pop3

JeReK5542 · #1 05.01.2014, 01:30

Добрый вечер!
У мене такая проблема:
подключаюсь к почте через idpop3 и idmessage и вывожу письма(от кого пришло, тема письма и так далее).
Знаю, что проблема с кодировкой, но незнаю как решить.
Вот скрин:

lmikle · #2 05.01.2014, 06:53

Есть такое дело. Indy не умеет расшифровывать такого вида кодировки автоматически. Вот я для себя писал такую штуку:

Код:

unit EmlStrUtils;

interface

uses
  Windows, SysUtils, Classes, StrUtils;

function DecodeEmailString(S : String) : String;

implementation

uses
  IdCoder, IdCoder3to4, IdCoderMIME, IdCoderQuotedPrintable;

function Base64Decode(const EncodedText: string): String;
var
  Decoder: TIdDecoderMIME;
begin
  Result := EncodedText;
  Decoder := TIdDecoderMIME.Create(nil);
  try
    Result := Decoder.DecodeString(EncodedText);
  finally
    Decoder.Free;
  end;
end;

function QuotedPrintableDecode(const EncodedText: string): String;
var
  Decoder: TIdDecoderQuotedPrintable;
begin
  Result := EncodedText;
  Decoder := TIdDecoderQuotedPrintable.Create(nil);
  try
    Result := Decoder.DecodeString(EncodedText);
  finally
    Decoder.Free;
  end;
end;

function DecodeTocken(S : String) : String;
var
  SecondQuestIdx : Integer;
  ThirdQuestIdx : Integer;
  Txt : String;
begin
  // =?charset?encoding?encoded text?=
  // =?utf-8?B?<text>?=
  // =?utf-8?Q?=D0=A5=D0=B0=D0=B9=D0=B9_...=21=21=21=29_?=

  Result := S;
  If Pos('=?',S) = 1 Then
    Begin
      SecondQuestIdx := PosEx('?',S,3);
      ThirdQuestIdx := PosEx('?',S,SecondQuestIdx+1);
      Txt := Copy(S,ThirdQuestIdx+1,Length(S)-ThirdQuestIdx-2);

      Case S[SecondQuestIdx+1] Of
        'B', 'b' :
          Begin
            Result := Base64Decode(Txt);
            If CompareText('utf-8',Copy(S,3,SecondQuestIdx-1-2)) = 0
              Then Result := Utf8ToAnsi(Result);
          End;
        'Q', 'q' :
          Begin
            Result := QuotedPrintableDecode(Txt);
          End;
      End;
    End;
end;

procedure SplitTockens(S : String; var AList : TStringList);
var
  Idx1, Idx2, Idx3 : Integer;
begin
  While S <> '' Do
    Begin
      Idx1 := Pos('=?',S);
      If Idx1 = 0
        Then
          Begin
            AList.Add(S);
            S := '';
          End
        Else
          If Idx1 > 1
            Then
              Begin
                AList.Add(Copy(S,1,Idx1-1));
                S := Copy(S,Idx1,Length(S));
              End
            Else
              Begin
                Idx2 := PosEx('?',S,3);
                Idx3 := PosEx('?',S,Idx2+1);
                AList.Add(Copy(S,1,PosEx('?=',S,Idx3+1)+1));
                S := Copy(S,PosEx('?=',S,Idx3+1)+2,Length(S));
              End;
    End;
end;

function DecodeEmailString(S : String) : String;
var
  I : Integer;
  AList : TStringList;
begin
  // =?charset?encoding?encoded text?=
  // =?utf-8?B?<text>?=
  // =?utf-8?Q?=D0=A5=D0=B0=D0=B9=D0=B9_...=21=21=21=29_?=

  Result := S;
  If Pos('=?',S) <> 0 Then
    Begin
      Result := '';
      AList := TStringList.Create;
      Try
        // Split tockens
        SplitTockens(S,AList);

        // Decode
        For I := 0 To AList.Count-1 Do
          AList[i] := DecodeTocken(AList[i]);

        // Join result
        For I := 0 To AList.Count-1 Do
          Result := Result + AList[i];
      Finally
        AList.Free;
      End;
    End;
end;

end.

JeReK5542 · #3 05.01.2014, 09:10

как использовать ваш код?

вообщем я создал файл EmlStrUtils.pas и закинул туда ваш код, после етого подключил его после

Цитата:

implementation

uses EmlStrUtils;

и использовал так
DecodeEmailString(idmessage1.subject)
и заработало)
спасибо за помощь)

помогите пожалуйста решить еще одну проблему с содержимым письма

и как распозновать html символы?

lmikle · #4 05.01.2014, 18:42

Это еще не делал (но собираюсь).
В принципе, можно попробовать прогнать через MSHTML и у него попросить вернуть "чистый" текст. Хотя тут надо дольше ковыряться.

Кстати, обведенное на картинке очень похоже либо на KOI8 или на нераскодированный Base64 (первая строчка, остальные 2 это скорее KOI8).

JeReK5542 · #5 05.01.2014, 18:48

первая обведенная строчка ето base64, а вот с остальным незнаю че делать(

lmikle · #6 05.01.2014, 22:24

Я же говорю, что это похоже на KOI8R.
Скорее всего где-то в заголовках или еще где есть указание на то, в какой кодировке текст. Тебе надо найти это место и из указанной перекодировать в 1251. Это уже руками. Готового решения от Indy не жди, т.к. это специфичная задача. Но можно попробовать поискать по русским сайтам... например здесь: http://www.delphisources.ru/pages/fa...1251_koi8.html

Тебе осталось только найти имя этой кодировки в письме.

Кстати, если кто еще читает эту тему. Какие самые употребительные кодировки в мире? Не только русские...

PhoeniX · #7 05.01.2014, 22:41

UTF-8. Почти везде.
Потом идёт 1251, 1252.
Встречаются ISO-8859-1 и ISO-8859-15.
Ну и реже можно встретить какие-нибудь семибитные.

Freeman · #8 06.01.2014, 02:41

Цитата:

Сообщение от lmikle

Какие самые употребительные кодировки в мире?

Если брать по числу пользователей, популярными вполне могут оказаться Big5, GB18030 и Shift-JIS. Чтобы не быть голословным, вот тут -- GBK.

JeReK5542 · #9 06.01.2014, 14:52

я попробую както решить проблему с кодировкой, но если ктото знает, как ето все решить напишите пожалуйста)

JeReK5542 · #10 06.01.2014, 18:20

вообщем проблема осталась нерешённой(

Alegun · #11 07.01.2014, 00:47

Вот ещё в довесок к теме - преобразование Win1251 <-> Koi8r

Код:

type TConvertChars = array[#128..#255] of char;

const Win_KoiChars: TConvertChars = 
(#128,#129,#130,#131,#132,#133,#134,#135,#136,#137,#060,
 #139,#140,#141,#142,#143,#144,#145,#146,#147,#148,#169,
 #150,#151,#152,#153,#154,#062,#176,#157,#183,#159,#160,
 #246,#247,#074,#164,#231,#166,#167,#179,#169,#180,#060,
 #172,#173,#174,#183,#156,#177,#073,#105,#199,#181,#182,
 #158,#163,#191,#164,#062,#106,#189,#190,#167,#225,#226,
 #247,#231,#228,#229,#246,#250,#233,#234,#235,#236,#237,
 #238,#239,#240,#242,#243,#244,#245,#230,#232,#227,#254,
 #251,#253,#154,#249,#248,#252,#224,#241,#193,#194,#215,
 #199,#196,#197,#214,#218,#201,#202,#203,#204,#205,#206,
 #207,#208,#210,#211,#212,#213,#198,#200,#195,#222,#219,
 #221,#223,#217,#216,#220,#192,#209);  

Koi_WinChars: TConvertChars = 
(#128,#129,#130,#131,#132,#133,#134,#135,#136,#137,#138,
 #139,#140,#141,#142,#143,#144,#145,#146,#147,#148,#149,
 #150,#151,#152,#153,#218,#155,#176,#157,#183,#159,#160,
 #161,#162,#184,#186,#165,#166,#191,#168,#169,#170,#171,
 #172,#173,#174,#175,#156,#177,#178,#168,#170,#181,#182,
 #175,#184,#185,#186,#187,#188,#189,#190,#185,#254,#224,
 #225,#246,#228,#229,#244,#227,#245,#232,#233,#234,#235,
 #236,#237,#238,#239,#255,#240,#241,#242,#243,#230,#226,
 #252,#251,#231,#248,#253,#249,#247,#250,#222,#192,#193,
 #214,#196,#197,#212,#195,#213,#200,#201,#202,#203,#204,
 #205,#206,#207,#223,#208,#209,#210,#211,#198,#194,#220,
 #219,#199,#216,#221,#217,#215,#218);

function Win_KoiConvert(const St: string): string;
var 
 i: integer;
begin 
 Result:=St;  
 for i:=1 to Length(St) do
  if St[i]>#127 then Result[i]:=Win_KoiChars[St[i]];
end;

©Drkb::04287

JeReK5542 · #12 07.01.2014, 20:07

если ктонибуть решит ету проблему, напишите пожалуйста сюда решение

JeReK5542 · #13 13.01.2014, 15:48

ну что некто так и незнает как решить?(

Опции темы	Поиск в этой теме
Версия для печати Отправить на Email	Поиск в этой теме: Расширенный поиск
Опции просмотра
Линейный вид Комбинированный вид Древовидный вид

	Сайт	Форум	FAQ	Соглашения	Прочее
	Новости Исходники Компоненты Статьи Добавить исходник Поиск	Правила Поиск Сообщения за сегодня Пользователи Кто на форуме?	Delphi FAQ - 5000 статей DRKB - 4500 статей (ZIP-архив) Справочник функций и процедур Delphi Delphi Programming Guide Indy in Depth. Глубины Indy	Конфиденциальность Соглашение пользователя Правила обработки cookie	О сайте Donate Контакты

Этот пользователь сказал Спасибо lmikle за это полезное сообщение:
JeReK5542 (05.01.2014)