[OkSherd]

Доброго времени суток. Столкнулся с такой вот проблемой:
Есть вполне работоспособная и очень даже неплохая функция для копирования файлов и каталогов с файлами и подкаталогами

Код:

function FullDirectoryCopy(SourceDir, TargetDir: String;
  StopIfNotAllCopied, OverWriteFiles: Boolean): Boolean;
{StopIfNotAllCopied: если значение этого аргумента = True, то при
первой же ошибке копирования файла или папки, работы функции прекратится
а функуция вернёт False. В случае если этот аргумент = False,
то ошибки копирования учитываться не будут.
OverWriteFiles: если True, то существующие файлы будут переписаны.}
Var
  SR: TSearchRec;
  I: Integer;
Begin
  Result:=False;
  SourceDir:= IncludeTrailingBackslash(SourceDir);
  TargetDir:= IncludeTrailingBackslash(TargetDir);
  If Not DirectoryExists(SourceDir) Then
    Exit;
  If Not ForceDirectories(TargetDir) Then
    Exit;
    I:=FindFirst(SourceDir + '*', FaAnyFile, SR);
  Try
    While I = 0 Do
    Begin
      If (SR.Name <> '') And (SR.Name <> '.') And (SR.Name <> '..') Then
      Begin
        If SR.Attr = FaDirectory Then
          Result:= FullDirectoryCopy(SourceDir + SR.Name, TargetDir + SR.NAME,
          StopIfNotAllCopied, OverWriteFiles)
        Else
        If Not (Not OverWriteFiles And FileExists(TargetDir + SR.Name)) Then
          Result:= CopyFileEx(Pchar(SourceDir + SR.Name), Pchar(TargetDir + SR.Name), @CopyCallBack,nil,nil,0) //гдеCopyCallBack - ф-я для индикации прогресса
        Else
          Result:=True;
        If Not Result And StopIfNotAllCopied Then
          Exit;
      End;
      I:=FindNext(SR);
    End;
  Finally
    SysUtils.FindClose(SR);
  End;
End;

Также есть работоспособная функция для определения даты модификации файла

Код:

function FileTimeModifyed(const FileName: string): TDateTime;
var
  Handle: THandle;
  FindData: TWin32FindData;
  LocalFileTime: TFileTime;
begin
  try
    Handle := FindFirstFile(PChar(FileName), FindData);
    if Handle <> INVALID_HANDLE_VALUE then
    begin
      Windows.FindClose(Handle);
        FileTimeToLocalFileTime(FindData.ftLastWriteTime, LocalFileTime);
        FileTimeToDosDateTime(LocalFileTime, LongRec(Handle).Hi, LongRec(Handle).Lo);
    end;
    Result := FileDateToDateTime(Handle);
  finally
  end;
end;

Проблема состоит в том что бы как то связать этих 2 функции в одну и что бы при копировании сначала файлы сверялись на дату последней модификации и потом более старые заменялись на новые.
Заранее всем откликнувшимся выношу свою благодарность

[poli-smen]

Сообщение от OkSherd

.....
Проблема состоит в том что бы как то связать этих 2 функции в одну и что бы при копировании сначала файлы сверялись на дату последней модификации и потом более старые заменялись на новые.
Заранее всем откликнувшимся выношу свою благодарность

Переделай это условие:

Код:

If Not (Not OverWriteFiles And FileExists(TargetDir + SR.Name)) Then

на такое:

Код:

if not FileExists(TargetDir + SR.Name) or (OverWriteFiles and (FileTimeModifyed(TargetDir + SR.Name) < FileTimeModifyed(SourceDir + SR.Name))) then

Тогда при указании OverWriteFiles=True будут перезаписываться только старые файлы, а при указании OverWriteFiles=False вообще не будут перезаписываться существующие файлы.

p.s. Узнать время модификации файла можно и проще.

[Страдалецъ]

p.s. Узнать время модификации файла можно и проще.

Не только проще, но и короче. У вас функция FullDirectoryCopy работает с переменной SR которая содержит всю нужную инфу по файлу, в том числе и даты создания, изменения, открытия.

[OkSherd]

Большое спасибо, все работает. Теорию я понял, нужно повозиться с параметром Time переменной TSearchRecord. Буду дерзать.