[morebeauty]

Подскажите, можно ли передать в TEdit.Text не переменную типа string, а указатель на такую переменную? Ну, то есть чтобы TEdit постоянно отображал значение нужной мне текстовой переменной и изменял его (при вводе текста).

[NumLock]

>>>>>>>нет

[Alegun]

Сообщение от morebeauty

...чтобы TEdit постоянно отображал значение нужной мне текстовой переменной и изменял его (при вводе текста).

Код:

procedure TForm1.Edit1Change(Sender: TObject);
begin
MyTextVar:= Edit1.Text; // Edit1.Text при вводе равно MyTextVar
end;

и гденить в коде

Код:

...
MyTextVar:= 'Изменяюсь';
Edit1.Text:= MyTextVar; // индикатор
...

[angvelem]

А как же это?

Сообщение от morebeauty

... чтобы TEdit постоянно отображал значение нужной мне текстовой переменной и изменял его (при вводе текста).

[Alegun]

Оффтоп:

Сообщение от angvelem

А как же это?

По-русски это значит: и нашим, и вашим

[lmikle]

Сообщение от Alegun

Оффтоп:
По-русски это значит: и нашим, и вашим

вообще, в XE3 появилось что-то типа LiveBinding... может это в ту сторону (сам не проверял, не знаю). Но даже без этого, можно, конечно, извратиться, но придется делать свой тип и компонент. В компоненте надо сделать ссылку на тип и, соответсвенно, при изменении данных в поле ввода, писать в указанную переменную (если назначена). Ну а тип можно сделать типа такого:

Код:

type
  TOnStringChange = procedure (Sender : TObject; const Value : String) of object;
  TBindedString = class
  private
    FOnChange : TOnStringChange;
    FData : String
    procedure Set(Value : String);
  public
    constructor Create; virtual;

    property Data : String read FData write Set; default;
    property OnChnage : TOnStringChange read FOnChange write FOnChange;
  end;

implementation

constructor TBindedString.Create;
begin
  inherited;
  FData := '';
  FOnChnage := Nil;
end;

procedure TBindedString.Set(Value : String);
begin
  If FData <> Value Then
    Begin
      FData := Value;
      If Assigned(FOnChange) Then FOnChange(Self,FData);
   End;
end;

что-то типа так. Ну и теперь надо сделать наследника TEdit, который умеет с таким объектом работать. Получится вот такой биндинг

[Alegun]

Сообщение от lmikle

...можно, конечно, извратиться, но придется делать свой тип и компонент...

Да, всё это интересно, но эмпирически, с познавательной стороны вопроса (правда слегка напоминает афоризм из мультика "Крылья, ноги, хвост" -"Лучше день потерять, а потом за пять минут долететь." :-) Больно затратно, а ТС похоже нужно всего лишь отслеживать изменения в содержании какой-то переменной в рантайме.
Проще создать процедуру-индикатор

Код:

procedure Ind(ds: string);
begin
Form1.Edit1.Text:= ds;
end;
...
Prm:=Prm+text;
Ind(Prm); // вызывается каждый раз после внесения изменений
...

И всё.

[lmikle]

Сообщение от Alegun

Да, всё это интересно, но эмпирически, с познавательной стороны вопроса (правда слегка напоминает афоризм из мультика "Крылья, ноги, хвост" -"Лучше день потерять, а потом за пять минут долететь." :-) Больно затратно, а ТС похоже нужно всего лишь отслеживать изменения в содержании какой-то переменной в рантайме.
Проще создать процедуру-индикатор

Именно так. Т.е. для нормальной поддержки придется написать либо весь набор компонентов (поправить существующий), либо как-то извращаться с RTTI. Для простой задачи - явный оверхед. Но такое сделать вполне реально, что я и показал. Я бы покопал в сторону LiveBinding, но тогда это будет только для XE2/XE3. Лично мне это не нужно, хотя, писать тупой код "из переменной в контрол, потом обратно" действительно порядком надоело. Но тут может имеет смысл посмотреть в сторону написания какого-нить визарда.

[icWasya]

А обязательно это именно переменная? А нельзя эту строку сделать свойством? И сделать прямо так

Код:

  property MyString :string read GetMyString Write SetMyString;
function TForm1.GetMyString:String;
begin
  Result:=Edit1.Text;
end;
procedure TForm1.SetMyString(const Value:String);
begin
  Edit1.Text:=Value;
end;

[NumLock]

если в TEdit и String всегда одно и тоже значение, то кто-то лишний, либо TEdit, либо String. если строка меняется пользователем, то лишний String.

[morebeauty]

и гденить в коде

Код:

...
MyTextVar:= 'Изменяюсь';
Edit1.Text:= MyTextVar; // индикатор
...

Вот такого я и хотел избежать. Ибо таких кусков в коде немерено.

Код:

procedure TForm1.Edit1Change(Sender: TObject);

Отслеживает изменение Edit1.Text
Вот мне бы подошло событие на изменение переменной. Вопрос, как создать сие событие, если это возможно?

Можно было бы, конечно, не использовать отдельную стринговую переменную, а использовать напрямую Edit1.Text, но здесь возникли бы неудобства. Например, не всегда он должен отображать эту переменную. Иногда другую. То есть при изменении переменной каждый раз еще и условие должно выполняться. А порой и не одно. То есть в предложенном

Код:

...
MyTextVar:= 'Изменяюсь';
Edit1.Text:= MyTextVar; // индикатор
...

будет уже

Код:

...
MyTextVar:= 'Изменяюсь';
if Condition1 then
if Condition2 then
Edit1.Text:= MyTextVar; // индикатор
...

Ну да и ладно. Если это великая заморочь, то не стоит оно того. Буду копипастить код.

[Alegun]

Сообщение от morebeauty

...Вот мне бы подошло событие на изменение переменной...

Вижу только один способ, как такое отслеживать попроще - через таймер с минимальным периодом

Код:

procedure TForm1.Timer1Timer(Sender: TObject);
begin
if Condition1 then Edit1.Text:= MyTextVar1;
if Condition2 then Edit1.Text:= MyTextVar2;
end;

Если машинку особо не жалко, то такой изврат в самый раз.

[morebeauty]

Вижу только один способ, как такое отслеживать попроще - через таймер с минимальным периодом

Это первое, что мне пришло в голову. К сожалению, машинку жалко )

[Aristarh Dark]

Использовать таймер - это совсем уж изврат.
Можно сделать что-то типа такого:

Код:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TSomeType = class
  private
    FEdit: TEdit;
    function GetCaption: string;
    procedure SetCaption(const Value: string);
  public
    property Caption:string read GetCaption write SetCaption;
    property EditObject:TEdit read FEdit write FEdit;
  end;
  TForm1 = class(TForm)
    Edit1: TEdit;
    Button1: TButton;
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
    FSomeObject:TSomeType;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TSomeType }

function TSomeType.GetCaption: string;
begin
  if FEdit<>nil then
    Result:=FEdit.Text;
end;

procedure TSomeType.SetCaption(const Value: string);
begin
  if FEdit<>nil then
    FEdit.Text:=Value;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  FSomeObject.Caption:=Button1.Caption;
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  FSomeObject.Free;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  FSomeObject:=TSomeType.Create;
  FSomeObject.EditObject:=Edit1;
end;

end.

[NumLock]

где-то ошибка в техзадании:

Сообщение от morebeauty

чтобы TEdit постоянно отображал значение нужной мне текстовой переменной

.vs.

Сообщение от morebeauty

не всегда он должен отображать эту переменную

???