[Elvis]

Необходимо изменить программу http://www.delphisources.ru/pages/so...year/lamp.html так, что б под темным фоном был не скрин рабочего стола, а заданное изображение.

Код:

var
  Form1: TForm1;
  orig, temp: TBitmap;
  r : TRect;
  hypotenuse : Array of Array of Integer;


procedure TForm1.FormCreate(Sender: TObject);
var
  c : TCanvas;
  i, j : Integer;
begin
  DoubleBuffered := true;
  ShowCursor(false);
  Top := 0;
  Left := 0;
  ClientWidth := Screen.Width;
  ClientHeight := Screen.Height;
  r := Rect(0 , 0, ClientWidth, ClientHeight);
  orig := TBitmap.Create;
  orig.PixelFormat := pf24Bit;
  orig.Width := ClientWidth;
  orig.Height := ClientHeight;
  temp := TBitmap.Create;
  temp.Canvas.Brush.Color := clBlack;
  temp.PixelFormat := pf24Bit;
  temp.Width := ClientWidth;
  temp.Height := ClientHeight;
  c := TCanvas.Create;
  try
    c.Handle := GetWindowDC(GetDesktopWindow);  // насколько я понял - эта процедура "подкладывает" рабочий стол под тьму.
    orig.Canvas.CopyRect(r, c, r);
  finally
    c.Free;
  end;
  Canvas.Draw(0, 0, orig);
  setLength(hypotenuse, d+1, d+1);
  for i := 0 to d do for j := 0 to d do hypotenuse[i, j] := Round(Hypot(i, j));
end;

Но присвоить изображение переменным с или orig не удалось.

[Anklav]

Вот то что ты подписал, это и есть присвоение битмапу orig, изображения рабочего стола.

Код:

c.Handle := GetWindowDC(GetDesktopWindow);  //узнаем хандл рабочего стола и присваиваем его хандлу канваса "с"
orig.Canvas.CopyRect(r, c, r); // копируем изображение в битмап

CopyRect(Dest:Trect;Canvas:TCanvas; Source:TRect) Выполняет копирование прямоугольника Source из канвы Canvas в прямоугольник Dest в области самого объекта (нашел в первой ссылке)

А в коде который ты выложил, я вообще не вижу как рисуется затемнение.

Собственно вот здесь у тебя заполняется битмап темп, который и рисует свечение:

Код:

procedure TForm1.FormMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
var
  i, j, x0, x1, y0, y1, h : Integer;
  O, T : PRGBArray;
begin
  x0 := max(0, X - d);
  x1 := min(orig.Width-1, X + d);
  y0 := max(0, Y - d);
  y1 := min(orig.Height-1, Y + d);
  temp.Canvas.FillRect(r);
  for j := y0 to y1 do begin
    O := orig.Scanline[j];
    T := temp.ScanLine[j];
    for i := x0 to x1 do begin
      h := hypotenuse[Abs(X-i), Abs(Y-j)];
      if h < d then begin
        h := Trunc(h/d*255);
        T[i].rgbtRed := max(0, O[i].rgbtRed - h);
        T[i].rgbtGreen := max(0, O[i].rgbtGreen - h);
        T[i].rgbtBlue := max(0, O[i].rgbtBlue - h);
      end;
    end;
  end;
  Repaint;
end;

[Elvis]

Код:

c.Handle := GetWindowDC(GetDesktopWindow);
orig.Canvas.CopyRect(r, c, r);

как изменить код, чтоб присвоить заданное изображение, а не изображение рабочего стола? Ни к чему не пришел - постоянно упираюсь в типы данных.

[Anklav]

Nы ж небось в TBitMap грузишь jpg?

Код:

orig.LoadFromFile

(изображение должно быть формата BMP )

или

Код:

uses JPEG
...

var
j:TJpegImage;
...
begin
...
j:=TJpegImage.Create;
j.LoadFromFile('***.jpg');
orig.Assign(j);
j.free;

[Elvis]

Оба способа пробовал - результат один - вместо подкладки изображения под темноту получается "не просвещаемый" прямоугольник, размером загружаемого изображения изображения.
Скрин: http://clip2net.com/s/2Kj05

[Anklav]

Не знаю, что ты там пробовал, перед тем как постить код, я обычно его проверяю. У меня все работало замечательно.

Код:

procedure TForm1.FormCreate(Sender: TObject);
var
  i, j : Integer;
begin
  DoubleBuffered := true;
  ShowCursor(false);
  Top := 0;
  Left := 0;
  ClientWidth := Screen.Width;
  ClientHeight := Screen.Height;
  r := Rect(0 , 0, ClientWidth, ClientHeight);
  orig := TBitmap.Create;
  orig.PixelFormat := pf24Bit;
  temp := TBitmap.Create;
  temp.Canvas.Brush.Color := clBlack;
  temp.PixelFormat := pf24Bit;
  temp.Width := ClientWidth;
  temp.Height := ClientHeight;
  orig.LoadFromFile('файл.bmp');
  Canvas.Draw(0, 0, orig);
  setLength(hypotenuse, d+1, d+1);
  for i := 0 to d do for j := 0 to d do hypotenuse[i, j] := Round(Hypot(i, j));
end;