[M.A.D.M.A.N.]

На, не мучайся, за тебя уже все сделали.

http://www.delphisources.ru/pages/fa...arch_file.html

[MoS]

Сообщение от M.A.D.M.A.N.

На, не мучайся, за тебя уже все сделали.

http://www.delphisources.ru/pages/fa...arch_file.html

спс, буду разбираться

[sariman]

Или вот еще http://www.delphisources.ru/forum/sh...376#post116376, создавал подобную тему на форуме, добавляет в листбокс все файлы с папок и подпапок.

[angvelem]

Или ешё.

Код:

procedure FindFiles(const Path : String);
var
  SR  : TSearchRec;
  Ext : String;
begin
  if FindFirst(ExpandFileName(Path + '\*.*'), faAnyFile, SR) = 0 then
  try
    repeat
      if ((SR.Attr and faDirectory) <> 0) and (SR.Name[1] <> '.') then
        FindFiles(ExpandFileName(Path + '\' + SR.Name))
      else if (SR.Name[1] <> '.') then
        ListBox1.Items.Add(SR.Name);
    until FindNext(SR) <> 0;
  finally
    FindClose(SR);
  end;
end;

[MoS]

Сообщение от angvelem

Или ешё.

Код:

procedure FindFiles(const Path : String);
var
  SR  : TSearchRec;
  Ext : String;
begin
  if FindFirst(ExpandFileName(Path + '\*.*'), faAnyFile, SR) = 0 then
  try
    repeat
      if ((SR.Attr and faDirectory) <> 0) and (SR.Name[1] <> '.') then
        FindFiles(ExpandFileName(Path + '\' + SR.Name))
      else if (SR.Name[1] <> '.') then
        ListBox1.Items.Add(SR.Name);
    until FindNext(SR) <> 0;
  finally
    FindClose(SR);
  end;
end;

Спасибо, именно этот код очень помог!

[MoS]

Код:

procedure FindFiles(const Path : String);
var
  SR  : TSearchRec;
  Ext : String;
begin
  if FindFirst(ExpandFileName(Path + '\*.*'), faAnyFile, SR) = 0 then
  try
    repeat
      if ((SR.Attr and faDirectory) <> 0) and (SR.Name[1] <> '.') then
        FindFiles(ExpandFileName(Path + '\' + SR.Name))
      else if (SR.Name[1] <> '.') then
        ListBox1.Items.Add(SR.Name);
    until FindNext(SR) <> 0;
  finally
    FindClose(SR);
  end;
end;

возник вопрос, почему в этом коде при указании маски допустим *.txt не ищет файлы в подпапках?

[poli-smen]

Сообщение от MoS

возник вопрос, почему в этом коде при указании маски допустим *.txt не ищет файлы в подпапках?

Потому что маска "*.txt" исключает "из обзора" всё что не имеет расширения ".txt". Не только файлы, но и папки.
Другими словами этот код с маской "*.txt" не увидит ни файлов ни папок у которых расширение не ".txt", а раз он не увидит папку, то и не войдёт в неё.

[Bargest]

Значит все-таки есть костыль для *.*. Прикольно.
to ТС:
Перебирать надо папки (с маской * и проверять атрибут faDirectory), а потом в папке отдельно запускать поиск *.txt.

[poli-smen]

Сообщение от Bargest

Значит все-таки есть костыль для *.*. Прикольно.

Ну да, у винды тяжкое наследие DOS-а. Даже если в имени файла нет точки и вроде не должно быть расширения, но всё равно считается что расширение есть, просто пустое. Например папка с именем "TEMP" представляется как "TEMP." - т.е. 4 символа имя, 0 символов расширение и точка между ними. Поэтому под виндой маска "*.*" работает всегда.

p.s. Ещё пример тяжкого наследия DOS-а - нельзя создать папку или файл например с таким именем: "con.txt"

[Alegun]

Оффтоп: Офигеть, и вправду нельзя такой файл создать, во приколка:-О!

Небольшой пример по поиску: http://www.delphisources.ru/forum/sh...ad.php?t=10003

[NumLock]

можно:

-создать папку temp.
md \\?\d:\Downloads\temp.

-создать файл con.txt
type nul > \\?\d:\Downloads\con.txt

[MoS]

Помогите переписать этот код для поиска с маской в подпапках!

Код:

procedure FindFiles(const Path : String);
var
  SR  : TSearchRec;
  Ext : String;
begin
  if FindFirst(ExpandFileName(Path + '\*.*'), faAnyFile, SR) = 0 then
  try
    repeat
      if ((SR.Attr and faDirectory) <> 0) and (SR.Name[1] <> '.') then
        FindFiles(ExpandFileName(Path + '\' + SR.Name))
      else if (SR.Name[1] <> '.') then
        ListBox1.Items.Add(SR.Name);
    until FindNext(SR) <> 0;
  finally
    FindClose(SR);
  end;
end;

[sariman]

Код:

procedure GetAllFiles(Path: string; ListBox: TListBox );
var
  sRec: TSearchRec;
  isFound: Boolean;
begin
  Path := IncludeTrailingPathDelimiter(Path);
  isFound := FindFirst(Path + '\*.*', faAnyFile, sRec) = 0;
  while isFound do
  begin
    if (sRec.Name <> '.') and (sRec.Name <> '..') then
    begin
      if (sRec.Attr and faDirectory) = faDirectory then
        GetAllFiles(Path + sRec.Name, ListBox);
      if Pos('.mp3', Copy(sRec.Name, Length(sRec.Name)-3, 4)) = 1 then
        ListBox.Items.Add(Path + sRec.Name);
      if Pos('.AAC', Copy(sRec.Name, Length(sRec.Name)-3, 4)) = 1 then
        ListBox.Items.Add(Path + sRec.Name);
    end;
    Application.ProcessMessages;
    isFound := FindNext(sRec) = 0;
  end;
  FindClose(sRec);
end;

[poli-smen]

Сообщение от MoS

Помогите переписать этот код для поиска с маской в подпапках!

Я делаю так:

Код:

procedure FindFiles(const Dir, Ext: string; ResultList: TStrings);

  procedure SubFind(const Path: string);
  var
    SR: TSearchRec;
  begin
    if FindFirst(Path + '*.*', faAnyFile, SR) = NO_ERROR then
    try
      repeat
        if (SR.Attr and faDirectory) = 0 then // File
        begin
          if AnsiSameText(Ext, ExtractFileExt(SR.Name)) then ResultList.Add(Path + SR.Name);
        end else // Dir
        begin
          if (SR.Name <> '.') and (SR.Name <> '..') then SubFind(Path + SR.Name + '\');
        end;
      until FindNext(SR) <> NO_ERROR;
    finally
      FindClose(SR);
    end;
  end;

begin
  SubFind(IncludeTrailingPathDelimiter(Dir));
end;

Подобный код я использую уже много лет и так часто, что могу гарантировать его полную работоспособность.

Пример использования:

Код:

procedure TForm1.Button1Click(Sender: TObject);
begin
  ListBox1.Items.BeginUpdate;
  try
    FindFiles('C:\WINDOWS', '.exe', ListBox1.Items);
  finally
    ListBox1.Items.EndUpdate;
  end;
end;