[bpeguk]

ПОЖАЛУЙСТА! Подскажите каким образом я могу нарисовать в делфи вот такую фигуру? Я пытался вытягивать элипс, но у меня ничего не получается. Спасибо.

[AlexSku]

Про этот трилистник нашёл уравнение в полярных координатах: R = sin3a, где угол a имеет 3 диапазона (т.к. R не может быть отрицательным из-за синуса): [0..60], [120..180], [240..300] градусов. Кидаем на форму PaintBox и в событии OnPaint рисуем 3 листочка:

Код:

implementation

uses Math;

{$R *.dfm}

procedure TForm1.PaintBox1Paint(Sender: TObject);
var
  x0, y0, I, N: Integer;
  Angle, R, s, c: Extended;
begin
  x0:= PaintBox1.Width div 2;
  y0:= PaintBox1.Height div 2;
  PaintBox1.Canvas.MoveTo(x0, y0);
  N:= 100;
  for I:= 0 to N do
  begin
    Angle:= ((Pi/3)*I)/N;
    SinCos(Angle, s, c);
    R:= Sin(3*Angle)*Min(x0, y0);
    PaintBox1.Canvas.LineTo(x0+Round(R*c), y0+Round(R*s));
  end;
  for I:= 0 to N do
  begin
    Angle:= ((Pi/3)*I)/N + 2*Pi/3;
    SinCos(Angle, s, c);
    R:= Sin(3*Angle)*Min(x0, y0);
    PaintBox1.Canvas.LineTo(x0+Round(R*c), y0+Round(R*s));
  end;
  for I:= 0 to N do
  begin
    Angle:= ((Pi/3)*I)/N - 2*Pi/3;
    SinCos(Angle, s, c);
    R:= Sin(3*Angle)*Min(x0, y0);
    PaintBox1.Canvas.LineTo(x0+Round(R*c), y0+Round(R*s));
  end;
end;

[bpeguk]

Огромное спасибо! Реально помогли.