[Vladimr]

Как узнать количество используемой памяти другим приложением зная его HWND?

Есть код

Код:

uses .., psAPI, Windows;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  pmc: PPROCESS_MEMORY_COUNTERS;
  cb: Integer;
begin
  Memo1.Lines.Clear;
  cb := SizeOf(_PROCESS_MEMORY_COUNTERS);
  GetMem(pmc, cb);
  pmc^.cb := cb;
  if GetProcessMemoryInfo(GetCurrentProcess(), pmc, cb) then
  begin
    Memo1.Lines.Add( FloatToStr(pmc^.WorkingSetSize/1024) + ' KB');
    Memo1.Lines.Add( FloatToStr(pmc^.PagefileUsage/1024) + ' KB');
  end;
  FreeMem(pmc);
end;

Но он выдает кол-во используемой памяти только у самого себя.

[Shaft]

Сообщение от Vladimr

выдает кол-во используемой памяти только у самого себя.

Ну правильно, в функцию GetProcessMemoryInfo первым передается ID нужного процесса. А там функция GetCurrentProcess она возвращает ID своей программы.

Если честно я не знаю как по HWND вычислить ID процесса, мне никогда такой подход не требовался, я обычно это узнавал по имени процесса

[Vladimr]

Можно узнать PID окна по его HWND использую функцию

Код:

GetWindowThreadProcessId(HWND,PID);

Но даже передавая pid процесса в

Код:

var
  pmc: PPROCESS_MEMORY_COUNTERS;
  cb: Integer;
 PID:DWORD; //pid процесса (как в диспетчере задач), найденный через HWND
begin
  Memo1.Lines.Clear;
  cb := SizeOf(_PROCESS_MEMORY_COUNTERS);
  GetMem(pmc, cb);
  pmc^.cb := cb;
  if GetProcessMemoryInfo(pid, pmc, cb) then
  begin
    Memo1.Lines.Add( FloatToStr(pmc^.WorkingSetSize/1024) + ' KB');
    Memo1.Lines.Add( FloatToStr(pmc^.PagefileUsage/1024) + ' KB');
  end;
  FreeMem(pmc);
end;

ничего не выводиться.

[Shaft]

Я обманул, судя по документации
BOOL GetProcessMemoryInfo(
[in] HANDLE Process,
[out] PPROCESS_MEMORY_COUNTERS ppsmemCounters,
[in] DWORD cb
);
не идентификатор нужно передавать а дескриптор
Вот так должно

Код:

procedure TForm1.Button1Click(Sender: TObject);
var
  pmc: PPROCESS_MEMORY_COUNTERS;
  cb: Integer;
  Proc: THandle;
  PID:DWORD; //pid процесса (как в диспетчере задач), найденный через HWND
begin
  Memo1.Lines.Clear;
  cb := SizeOf(_PROCESS_MEMORY_COUNTERS);
  GetMem(pmc, cb);
  pmc^.cb := cb;
  Proc := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ, False, PID);
  if GetProcessMemoryInfo(Proc, pmc, cb) then
  begin
    Memo1.Lines.Add( FloatToStr(pmc^.WorkingSetSize/1024) + ' KB');
    Memo1.Lines.Add( FloatToStr(pmc^.PagefileUsage/1024) + ' KB');
  end;
  FreeMem(pmc);
  CloseHandle(Proc);
end;

[Vladimr]

Все получилось.

функция

Код:

function EnumProcid (Wnd: HWnd; Param: LongInt): Boolean; stdcall; // Обязательно stdcall !!!
Var
    Nm:Array[0..255] of Char;  // буфер для имени
    Cs: Array[0..255] of Char; // буфер для класса
    PID:DWORD;
    Proc: THandle;
    pmc: PPROCESS_MEMORY_COUNTERS;
    cb: Integer;
    s:string;
Begin
    GetWindowText(Wnd,Nm,255); // считываем  текст заголовка окна
    GetClassName(Wnd,Cs,255); // считываем название класса окна

    cb := SizeOf(_PROCESS_MEMORY_COUNTERS);
    GetMem(pmc, cb);
    pmc^.cb := cb;

    GetWindowThreadProcessId(wnd,PID); //узнаем PID процесса через его HWND
    Proc := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ, False, PID); //пытаемся получить информацию о процессе

    if GetProcessMemoryInfo(proc, pmc, cb) then s:=FloatToStr(pmc^.WorkingSetSize/1024)+' / '+FloatToStr(pmc^.PagefileUsage/1024);

    if IsWindowEnabled(wnd) and IsWindowVisible(Wnd) then  Form1.ListBox1.Items.Add(inttostr(pid)+' / '+inttostr(wnd)+' / '+String(Cs)+' / '+String(Nm)+' / '+s); // Добавляем PID, HWND, название класса, заголовок окна и кол-во памяти в Кб
    EnumProcid := TRUE;  // продолжать искать окна…

    FreeMem(pmc);
    CloseHandle(Proc);
end;

Ее использование

Код:

procedure TForm1.Button6Click(Sender: TObject);
begin
    ListBox1.Items.Clear;         // Очистим список перед началом поисков
    EnumWindows (@EnumProcid, 0); // и скажем - искать
end;

Выводит PID и кол-во используемой памяти всех запущенных приложений как в диспетчере задач.