[Cheetos]

Вопрос собственно говоря в следующем: есть компонент - потомок TPanel, включающий в себя другой компонент, например, тоже TPanel. Как из первого получить доступ к свойствам второго?
У внедренного компонента имеется свойство Caption. После размещения нового компонента на форме в инспекторе объектов (в Design-time) я вижу и могу изменить значение свойства Caption, но при компиляции (в Runtime) это значение сбрасыется на изначальное - почему?
Код ниже:

Код:

unit PanInPan;

interface

uses
  SysUtils, Classes, Controls, ExtCtrls, Graphics, QStdCtrls;

type
  TPanInPan = class(TPanel)
  private
    FTitle: TPanel;
    { Private declarations }
  protected
    { Protected declarations }
  public
    { Public declarations }
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    { Published declarations }
    property Title: TPanel read FTitle write FTitle;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('My', [TPanInPan]);
end;

// Создание компонента
constructor TPanInPan.Create(AOwner: TComponent);
begin
  inherited create(AOwner);
  width:=500;
  Height:=300;
  FTitle:=TPanel.Create(Self);
  with FTitle do
    begin
        Width:= 100;
        Align:= alRight;
        BevelOuter:= bvNone;
        TabOrder:= 0;
        Color:=clRed;
        Name:='SubTitle';
        Caption:=Name;
    end;
  FTitle.Parent:=Self;
end;

// Уничтожение компонента
destructor TPanInPan.Destroy;
begin
  FTitle.Free;
  inherited;
end;
end.

[angvelem]

Для начала, бери за основу TCustomPanel. У большинства контролов имеется свойство Caption, зачем вводить своё, родного не достаточно?

[Cheetos]

Сообщение от angvelem

Для начала, бери за основу TCustomPanel. У большинства контролов имеется свойство Caption, зачем вводить своё, родного не достаточно?

Реально внедренный компонент на основе TCustomControl, а тот, в который внедряется первый, как раз на основе TCustomPanel. Для простоты понимания привел пример на основе TPanel

[angvelem]

Непонятно, что даёт вторая панель. Если для вывода дополнительного текста, то не удобнее ли переписать метод Paint?

[Cheetos]

Сообщение от angvelem

Непонятно, что даёт вторая панель. Если для вывода дополнительного текста, то не удобнее ли переписать метод Paint?

Я же поясняю, что это просто пример, на котором легко увидеть ту проблему, которая меня интересует и не больше.

[Cheetos]

[dr. F.I.N.]

Пробовал добавить stored?

Код:

property Title: TPanel read GetPanel write SetPanel stored true;

[Cheetos]

Сообщение от dr. F.I.N.

Пробовал добавить stored?

Код:

property Title: TPanel read GetPanel write SetPanel stored true;

Delphi Help:
The stored directive must be followed by True, False, the name of a Boolean field, or the name of a parameterless method that returns a Boolean value. For example,

property Name: TComponentName read FName write SetName stored False;

If a property has no stored directive, it is treated as if stored True were specified.

А вообще пробовал - не помогает.

Вопрос по-прежнему открыт

[dr. F.I.N.]

Кстати. Хороший пример с исходником уже имеется в D7 - TLabeledEdit. Не знаю, есть ли он выше Может стоит его поковырять?

[Cheetos]

Сообщение от dr. F.I.N.

Кстати. Хороший пример с исходником уже имеется в D7 - TLabeledEdit. Не знаю, есть ли он выше Может стоит его поковырять?

У меня триальная версия дельфи, исходников в комплекте нет - буду признателен, если выложишь что-нить полезное

[Cheetos]

По-ходу разобрался!
После создания вложенного компонента нужно было указать, что он является "подкомпонентом": FTitle.SetSubComponent(true);
Измененный кусок кода - может кому пригодится

Код:

// Создание компонента
constructor TPanInPan.Create(AOwner: TComponent);
begin
  inherited create(AOwner);
  width:=500;
  Height:=300;
  FTitle:=TPanel.Create(Self);
  with FTitle do
    begin
        Width:= 100;
        Align:= alRight;
        BevelOuter:= bvNone;
        TabOrder:= 0;
        Color:=clRed;
        Name:='SubTitle';
        Caption:=Name;
    end;
  FTitle.Parent:=Self;
  FTitle.SetSubComponent(true);
end;

Спасибо всем, кто откликнулся!