[ProperDoze]

Для своей программы хочу использовать потоки. Т.к. работаю с визуальными компонентами, то приходиться использовать метод Synchronize. Программа работает нормально, НО Delphi, почемуто подчеркивает Synchronize красным и пишет

Undeclared identifier 'Synchronize' at line 39

Вопросы:
1. С чем это может быть связано?
2. Как это исправить?
3. Почему заведомо описанный метод отмечается как не описанный?

[ProperDoze]

Как запустить поток повторно?

[lmikle]

Если он закончился, то только повторно его создав.

[ProperDoze]

Сообщение от lmikle

Если он закончился, то только повторно его создав.

С этим давно разобрался, спасибо!

А как быть с Synchronize?

Мне кажется, что мой поток не работает, как нужно. Потому, что без Application.ProcessMessages Форму не прорисовывает. Что делать?

[lmikle]

Как я могу тебе сказать, что ты делаешь не так, если я не вижу что и как ты делаешь? Код приведи, бум смотреть.

[ProperDoze]

Сообщение от lmikle

Как я могу тебе сказать, что ты делаешь не так, если я не вижу что и как ты делаешь? Код приведи, бум смотреть.

Ок.

Код:

unit Thread_Chart_repaint;

interface

uses
  Classes;

type
  Repaint_Charts = class(TThread)
  private
    { Private declarations }
  protected
    procedure Execute; override;
  public
    Processing: boolean;
  end;

implementation
  uses converter;
{ Important: Methods and properties of objects in visual components can only be
  used in a method called using Synchronize, for example,

      Synchronize(UpdateCaption);

  and UpdateCaption could look like,

    procedure Repaint_Charts.UpdateCaption;
    begin
      Form1.Caption := 'Updated in a thread';
    end; }

{ Repaint_Charts }

procedure Repaint_Charts.Execute;
begin
  //while not Terminated do
  //while Processing do
  Synchronize(Charts_panel.Paint_charts);
end;

end.

Synchronize подчеркнуто красным, но код исполняется.

[lmikle]

Скорее всего, она предупреждает тебя, что потенциально возможны проблемы, т.к. Synchronize в принципе предназначена для выполнения методов потока. А вот уже из метода потока, можно спокойно "дергать" что угодно.

[ProperDoze]

Сообщение от lmikle

Скорее всего, она предупреждает тебя, что потенциально возможны проблемы, т.к. Synchronize в принципе предназначена для выполнения методов потока. А вот уже из метода потока, можно спокойно "дергать" что угодно.

Тогда, почему она пишет "Undeclared identifier" а не какой нибудь варнинг??!

А также, поток работает, на мой взгляд, не так, как надо. Это выражается в том, что без потока, все работает аналогично!!!! Т.е. без применения Application.ProcessMessages события формы не "ловятся" и стало быть форма "сама" не прорисовывается.

З.Ы. Например, в даунлоад-мастере когда окно с загрузкой двигаешь по экрану, загрузка не приостанавливается, а это, на мой взгляд, говорит о том, что там используются как минимум потоки и никакого Application.ProcessMessages, т.к. он такого эффекта не дает.

[ProperDoze]

Кто нибудь может привести в пример код простой программы, где потоки нормально работают?!

[Drozh]

Вычисление числа ПИ

Главная форма

Код:

unit uMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls,
  uPiThread;

type
  TfmMain = class(TForm)
    cbCalculate: TCheckBox;
    Label1: TLabel;
    Label2: TLabel;
    laBuiltIn: TLabel;
    laValue: TLabel;
    laIterNum: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure cbCalculateClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
   PiThread : TPiThread;
   procedure UpdatePi;
  end;

var
  fmMain: TfmMain;

implementation

{$R *.dfm}

procedure TfmMain.UpdatePi;
begin
   if IsIconic( Application.Handle ) then 
    Exit;
  LaValue.Caption := FloatToStrF( GlobalPi, ffFixed, 18, 18 );
  laIterNum.Caption := IntToStr( GlobalCounter ) + ' iterations';
end;

procedure TfmMain.FormCreate(Sender: TObject);
begin
 laBuiltIn.Caption := FloatToStrF( Pi, ffFixed, 18, 18 );
end;

procedure TfmMain.cbCalculateClick(Sender: TObject);
begin
  if cbCalculate.Checked then
  begin
   PiThread := TPiThread.Create( True );
   PiThread.FreeOnTerminate := True;
   PiThread.Priority := tpLower;
   PiThread.Resume;
  end
 else
  begin
   if Assigned( PiThread ) then PiThread.Terminate;
  end;

end;

end.

Поток

Код:

unit uPiThread;

interface

uses
  Classes;

type
  TPiThread = class(TThread)
  private
    { Private declarations }
  protected
    procedure Execute; override;
  end;

 var
 GlobalPi : Extended;
 GlobalCounter : Int64;

implementation

uses uMain;

const
 UpdatePeriod = 999999;

procedure TPiThread.Execute;
var sign : Integer;
  PiValue, PrevValue : Extended;
  i : Int64;
begin
 PiValue := 4;
 sign := -1;
 i := 0;
 repeat
  Inc(i);
  PrevValue := PiValue;
  PiValue := PiValue + sign * 4 / (2*i+1);
  sign := -sign;
  if i mod UpdatePeriod = 0 then
   begin
    GlobalPi := PiValue;
    GlobalCounter := i;
    Synchronize( fmMain.UpdatePi );
   end;
 until Terminated or
 (Abs(PiValue - PrevValue)<1E-19) ;
end;

end.