[poli-smen]

"По просьбам трудящихся" наваял пример рисующий некую 3D-гистограмму на основе bmp-файла:

Код:

procedure TForm1.ButtonClick(Sender: TObject);
var
  bmp: TBitmap;
  BmpX, BmpY, X, Y, Z, TempX, TempY, BmpHalfWidth, BmpHalfHeight, Radius: Integer;
  Color: TColor;
  A, SinA, CosA, B, SinB, CosB, DY: Extended;
begin
  bmp := TBitmap.Create;
  try
    bmp.LoadFromFile('C:\WINDOWS\Ночной ковыль.bmp');
//    bmp.LoadFromFile('C:\WINDOWS\Пузыри.bmp');
//    bmp.LoadFromFile('C:\WINDOWS\Рододендрон.bmp');

    BmpHalfWidth := bmp.Width div 2;
    BmpHalfHeight := bmp.Height div 2;
    Radius := Trunc(Sqrt(Sqr(bmp.Width) + Sqr(bmp.Height)) / 2);

    A := DegToRad(30);
    SinA := Sin(A);
    CosA := Cos(A);

    B := DegToRad(20);
    SinB := Sin(B);
    CosB := Cos(B);

    DY := 256 * CosB;

    Repaint;

    for BmpY := 0 to bmp.Height - 1 do
    begin
      for BmpX := 0 to bmp.Width - 1 do
      begin
        Color := bmp.Canvas.Pixels[BmpX, BmpY];
        Z := (GetRValue(Color) + GetGValue(Color) + GetBValue(Color)) div 3;

        TempX := BmpX - BmpHalfWidth;
        TempY := BmpY - BmpHalfHeight;

        X := Trunc(TempX * CosA + TempY * SinA + Radius);
        Y := Trunc((TempY * CosA - TempX * SinA) * SinB + Radius + DY);

        Canvas.Pen.Color := Color;
        Canvas.MoveTo(X, Y);
        Canvas.LineTo(X, Y - Trunc(Z * CosB));
      end;
    end;
  finally
    bmp.Free;
  end;
end;

В этом примере высота столбика гистограммы просто среднее арифметическое значение трёх составляющих цвета пикселя.